Started splitting up user and home manager configuration

.gitignore

@@ -0,0 +1 @@
+result

system.nix

@@ -0,0 +1,12 @@
+{ config, lib, pkgs, ... }:
+
+{
+  options = {
+    custom.laptop = lib.mkOption {
+      type = lib.types.bool;
+      default = false;
+      example = true;
+      description = "Whether the current system is a laptop.";
+    };
+  };
+}

test.nix

@@ -0,0 +1,11 @@
+{ config, lib, pkgs, ... }:
+
+{
+  config = {
+    custom.users.jan = {
+      enable = true;
+      sudo = true;
+      configuration = ./users/jan.nix;
+    };
+  };
+}

users.nix

@@ -0,0 +1,46 @@
+{ config, lib, pkgs, ... }:
+
+let
+  userModule = lib.types.submodule {
+    options = {
+      enable = lib.mkOption {
+        type = lib.types.bool;
+        default = false;
+        example = true;
+        description = "Whether the user is enabled.";
+      };
+      sudo = lib.mkOption {
+        type = lib.types.bool;
+        default = false;
+        example = true;
+        description = "Whether the user is allowed sudo access.";
+      };
+      configuration = lib.mkOption {
+        type = lib.types.path;
+        default = ./users/base.nix;
+        description = "What home manager configuration to use for this user.";
+      };
+    };
+  };
+in {
+  options = {
+    custom.users = lib.mkOption {
+      type = lib.types.attrsOf userModule;
+      default = {};
+      description = "Users configured on this system.";
+    };
+  };
+
+  config = {
+    users.users = lib.attrsets.concatMapAttrs (name: value: {
+      ${name} = {
+        isNormalUser = true;
+        extraGroups = lib.mkIf value.sudo [ "wheel" ];
+      };
+    }) config.custom.users;
+
+    home-manager.users = lib.attrsets.concatMapAttrs (name: value: {
+      ${name} = value.configuration;
+    }) config.custom.users;
+  };
+}

users/base.nix

@@ -0,0 +1,8 @@
+{ ... }:
+
+{
+  imports = [
+    # Import all modules
+    ./modules/default.nix
+  ];
+}

users/jan.nix

@@ -0,0 +1,12 @@
+{ ... }:
+
+{
+  imports = [
+    # Import base configuration
+    ./base.nix
+  ];
+
+  config = {
+    modules.zathura.enable = true; 
+  };
+}

users/modules/default.nix

@@ -0,0 +1,10 @@
+{ input, pkgs, config, ... }:
+
+{
+  # Set the state version
+  home.stateVersion = "24.05";
+  
+  imports = [
+    ./tools/zathura/default.nix
+  ];
+}

users/modules/tools/zathura/default.nix

@@ -0,0 +1,17 @@
+{config, lib, pkgs, ... }:
+
+let
+  cfg = config.modules.zathura;
+in {
+  options.modules.zathura.enable = lib.mkEnableOption "zathura";
+
+  config = lib.mkIf cfg.enable {
+    programs.zathura = {
+      enable = true;
+
+      options = {
+        guioptions = "none";
+      };
+    };
+  };
+}