Reorganized

unorganized/user-modules/bluetuith/default.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.bluetuith;
+in
+{
+  options.modules.bluetuith = {
+    enable = mkEnableOption "bluetuith";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [ bluetuith ];
+
+    # Add nix tree
+    xdg.desktopEntries.bluetuith = {
+      exec = "${pkgs.bluetuith}/bin/bluetuith";
+      name = "Bluetuith";
+      terminal = true;
+      type = "Application";
+    };
+  };
+}

unorganized/user-modules/browser/default.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+{
+  imports = [
+    ./firefox/default.nix
+    ./qutebrowser/default.nix
+  ];
+
+  options.default.browser = mkOption {
+    type = types.str;
+    default = "";
+    description = "Default browser";
+  };
+
+  config = {
+    xdg.mimeApps = {
+      enable = true;
+
+      defaultApplications = {
+        "text/html" = "${config.default.browser}";
+        "x-scheme-handler/http" = "${config.default.browser}";
+        "x-scheme-handler/https" = "${config.default.browser}";
+        "x-scheme-handler/about" = "${config.default.browser}";
+        "x-scheme-handler/unknown" = "${config.default.browser}";
+      };
+    };
+  };
+}

unorganized/user-modules/browser/firefox/default.nix

@@ -0,0 +1,76 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.firefox;
+in
+{
+  options.modules.firefox = {
+    enable = lib.mkEnableOption "firefox";
+    default = lib.mkEnableOption "default";
+  };
+
+  config = lib.mkIf cfg.enable {
+    default.browser = mkIf cfg.default "firefox.desktop";
+
+    programs.firefox = {
+      enable = true;
+
+      policies = {
+        AppAutoUpdate = false;
+        BlockAboutAddons = false;
+        BlockAboutConfig = true;
+        BlockAboutProfiles = true;
+        DisableAppUpdate = true;
+        DisableFeedbackCommands = true;
+        DisableMasterPasswordCreation = true;
+        DisablePocket = true;
+        DisableProfileImport = true;
+        DisableProfileRefresh = true;
+        DisableSetDesktopBackground = true;
+        DisableTelemetry = true;
+        DisplayBookmarksToolbar = "never";
+        DisplayMenuBar = "never";
+        DNSOverHTTPS = {
+          Enabled = false;
+        };
+        DontCheckDefaultBrowser = true;
+        PasswordManagerEnabled = false;
+        TranslateEnabled = true;
+        UseSystemPrintDialog = true;
+      };
+
+      profiles.nixos = {
+        search.default = "ddg";
+
+        extensions.packages = with pkgs.nur.repos.rycee.firefox-addons; [
+          ublock-origin
+        ];
+
+        # Theming
+        userChrome = readFile (
+          pkgs.replaceVars ./userChrome.css {
+            colors = config.desktop.theming.colorsCSS;
+          }
+        );
+
+        settings = {
+          "browser.tabs.inTitlebar" = 0;
+          "extensions.autoDisableScopes" = 0;
+          "devtools.chrome.enabled" = true;
+          "devtools.debugger.remote-enabled" = true;
+          "toolkit.legacyUserProfileCustomizations.stylesheets" = true;
+        };
+
+        # Force overwriting configuration file
+        search.force = true;
+        containersForce = true;
+      };
+    };
+  };
+}

unorganized/user-modules/browser/firefox/userChrome.css

@@ -0,0 +1,73 @@
+/* Import theme colors */
+@colors@
+
+/* Configure titlebar */
+#titlebar {
+    /* Add consistent margins to tab bar */
+    padding: 0 2px !important;
+
+    /* Add emphasized color to background of tab bar */
+    background-color: var(--nix-color-bg-status) !important;
+
+    /* Set correct text color */
+    color: var(--nix-color-fg) !important;
+}
+
+.tab-background:is([selected], [multiselected]) {
+    /* Set correct background color */
+    background-color: var(--nix-color-bg) !important;
+}
+
+.tab-content {
+    /* Set correct text color */
+    color: var(--nix-color-fg) !important;
+}
+
+/* Configure navigation bar */
+#nav-bar {
+    /* Set correct background color */
+    background-color: var(--nix-color-bg) !important;
+
+    /* Set correct text color */
+    color: var(--nix-color-fg) !important;
+}
+
+#urlbar {
+    /* Set correct text color */
+    color: var(--nix-color-fg) !important;
+}
+
+#urlbar[open]>#urlbar-background {
+    /* Set correct background color when opened */
+    background-color: var(--nix-color-bg) !important;
+
+    /* Use same box-shadow as tabs when opened */
+    border: none !important;
+    box-shadow: 0 0 4px rgba(0, 0, 0, .4) !important;
+}
+
+#urlbar[focused]:not([suppress-focus-border])>#urlbar-background {
+    /* Set better outline for focused urlbar */
+    outline-color: var(--nix-color-border-focused) !important;
+    outline-width: 1px !important;
+    outline-offset: 0 !important;
+}
+
+#urlbar-background {
+    /* Set the correct background color */
+    background-color: var(--nix-color-bg-status) !important;
+}
+
+/* Configure popups */
+panelview {
+    /* Set correct background color for popups */
+    background-color: var(--nix-color-bg) !important;
+
+    /* Set correct text color */
+    color: var(--nix-color-fg) !important;
+}
+
+menupopup {
+    /* Set correct background color for context menus */
+    --panel-background: var(--nix-color-bg) !important;
+}

unorganized/user-modules/browser/qutebrowser/default.nix

@@ -0,0 +1,34 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.qutebrowser;
+  theme = config.desktop.theming;
+in
+{
+  options.modules.qutebrowser = {
+    enable = mkEnableOption "qutebrowser";
+    default = mkEnableOption "default";
+  };
+
+  config = mkIf cfg.enable {
+    default.browser = mkIf cfg.default "org.qutebrowser.qutebrowser.desktop";
+
+    programs.qutebrowser = {
+      enable = true;
+
+      extraConfig = ''
+        config.set("completion.web_history.max_items", 256)
+        config.set("colors.webpage.darkmode.enabled", False)
+        config.set("colors.webpage.preferred_color_scheme", "${if theme.darkMode then "dark" else "light"}")
+        config.set("fonts.default_family", "${theme.fonts.interface.name}")
+        config.set("fonts.default_size", "${toString theme.fonts.interface.recommendedSize}pt")
+      '';
+    };
+  };
+}

unorganized/user-modules/btop/default.nix

@@ -0,0 +1,368 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.btop;
+  colors = config.desktop.theming.schemeColors;
+in
+{
+  options.modules.btop = {
+    enable = mkEnableOption "btop";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [ btop ];
+
+    xdg.configFile."btop/btop.conf" = {
+      enable = true;
+      text = ''
+        #? Config file for btop v. 1.4.0
+
+        #* Name of a btop++/bpytop/bashtop formatted ".theme" file, "Default" and "TTY" for builtin themes.
+        #* Themes should be placed in "../share/btop/themes" relative to binary or "$HOME/.config/btop/themes"
+        color_theme = "nixos"
+
+        #* If the theme set background should be shown, set to False if you want terminal background transparency.
+        theme_background = True
+
+        #* Sets if 24-bit truecolor should be used, will convert 24-bit colors to 256 color (6x6x6 color cube) if false.
+        truecolor = True
+
+        #* Set to true to force tty mode regardless if a real tty has been detected or not.
+        #* Will force 16-color mode and TTY theme, set all graph symbols to "tty" and swap out other non tty friendly symbols.
+        force_tty = False
+
+        #* Define presets for the layout of the boxes. Preset 0 is always all boxes shown with default settings. Max 9 presets.
+        #* Format: "box_name:P:G,box_name:P:G" P=(0 or 1) for alternate positions, G=graph symbol to use for box.
+        #* Use whitespace " " as separator between different presets.
+        #* Example: "cpu:0:default,mem:0:tty,proc:1:default cpu:0:braille,proc:0:tty"
+        presets = "cpu:1:default,proc:0:default cpu:0:default,mem:0:default,net:0:default cpu:0:block,net:0:tty"
+
+        #* Set to True to enable "h,j,k,l,g,G" keys for directional control in lists.
+        #* Conflicting keys for h:"help" and k:"kill" is accessible while holding shift.
+        vim_keys = False
+
+        #* Rounded corners on boxes, is ignored if TTY mode is ON.
+        rounded_corners = False
+
+        #* Default symbols to use for graph creation, "braille", "block" or "tty".
+        #* "braille" offers the highest resolution but might not be included in all fonts.
+        #* "block" has half the resolution of braille but uses more common characters.
+        #* "tty" uses only 3 different symbols but will work with most fonts and should work in a real TTY.
+        #* Note that "tty" only has half the horizontal resolution of the other two, so will show a shorter historical view.
+        graph_symbol = "braille"
+
+        # Graph symbol to use for graphs in cpu box, "default", "braille", "block" or "tty".
+        graph_symbol_cpu = "default"
+
+        # Graph symbol to use for graphs in gpu box, "default", "braille", "block" or "tty".
+        graph_symbol_gpu = "default"
+
+        # Graph symbol to use for graphs in cpu box, "default", "braille", "block" or "tty".
+        graph_symbol_mem = "default"
+
+        # Graph symbol to use for graphs in cpu box, "default", "braille", "block" or "tty".
+        graph_symbol_net = "default"
+
+        # Graph symbol to use for graphs in cpu box, "default", "braille", "block" or "tty".
+        graph_symbol_proc = "default"
+
+        #* Manually set which boxes to show. Available values are "cpu mem net proc" and "gpu0" through "gpu5", separate values with whitespace.
+        shown_boxes = "cpu net proc mem"
+
+        #* Update time in milliseconds, recommended 2000 ms or above for better sample times for graphs.
+        update_ms = 500
+
+        #* Processes sorting, "pid" "program" "arguments" "threads" "user" "memory" "cpu lazy" "cpu direct",
+        #* "cpu lazy" sorts top process over time (easier to follow), "cpu direct" updates top process directly.
+        proc_sorting = "cpu lazy"
+
+        #* Reverse sorting order, True or False.
+        proc_reversed = False
+
+        #* Show processes as a tree.
+        proc_tree = False
+
+        #* Use the cpu graph colors in the process list.
+        proc_colors = True
+
+        #* Use a darkening gradient in the process list.
+        proc_gradient = True
+
+        #* If process cpu usage should be of the core it's running on or usage of the total available cpu power.
+        proc_per_core = False
+
+        #* Show process memory as bytes instead of percent.
+        proc_mem_bytes = True
+
+        #* Show cpu graph for each process.
+        proc_cpu_graphs = True
+
+        #* Use /proc/[pid]/smaps for memory information in the process info box (very slow but more accurate)
+        proc_info_smaps = False
+
+        #* Show proc box on left side of screen instead of right.
+        proc_left = False
+
+        #* (Linux) Filter processes tied to the Linux kernel(similar behavior to htop).
+        proc_filter_kernel = False
+
+        #* In tree-view, always accumulate child process resources in the parent process.
+        proc_aggregate = False
+
+        #* Sets the CPU stat shown in upper half of the CPU graph, "total" is always available.
+        #* Select from a list of detected attributes from the options menu.
+        cpu_graph_upper = "Auto"
+
+        #* Sets the CPU stat shown in lower half of the CPU graph, "total" is always available.
+        #* Select from a list of detected attributes from the options menu.
+        cpu_graph_lower = "Auto"
+
+        #* If gpu info should be shown in the cpu box. Available values = "Auto", "On" and "Off".
+        show_gpu_info = "Auto"
+
+        #* Toggles if the lower CPU graph should be inverted.
+        cpu_invert_lower = True
+
+        #* Set to True to completely disable the lower CPU graph.
+        cpu_single_graph = False
+
+        #* Show cpu box at bottom of screen instead of top.
+        cpu_bottom = False
+
+        #* Shows the system uptime in the CPU box.
+        show_uptime = True
+
+        #* Show cpu temperature.
+        check_temp = True
+
+        #* Which sensor to use for cpu temperature, use options menu to select from list of available sensors.
+        cpu_sensor = "Auto"
+
+        #* Show temperatures for cpu cores also if check_temp is True and sensors has been found.
+        show_coretemp = True
+
+        #* Set a custom mapping between core and coretemp, can be needed on certain cpus to get correct temperature for correct core.
+        #* Use lm-sensors or similar to see which cores are reporting temperatures on your machine.
+        #* Format "x:y" x=core with wrong temp, y=core with correct temp, use space as separator between multiple entries.
+        #* Example: "4:0 5:1 6:3"
+        cpu_core_map = ""
+
+        #* Which temperature scale to use, available values: "celsius", "fahrenheit", "kelvin" and "rankine".
+        temp_scale = "celsius"
+
+        #* Use base 10 for bits/bytes sizes, KB = 1000 instead of KiB = 1024.
+        base_10_sizes = False
+
+        #* Show CPU frequency.
+        show_cpu_freq = True
+
+        #* Draw a clock at top of screen, formatting according to strftime, empty string to disable.
+        #* Special formatting: /host = hostname | /user = username | /uptime = system uptime
+        clock_format = "%X"
+
+        #* Update main ui in background when menus are showing, set this to false if the menus is flickering too much for comfort.
+        background_update = True
+
+        #* Custom cpu model name, empty string to disable.
+        custom_cpu_name = ""
+
+        #* Optional filter for shown disks, should be full path of a mountpoint, separate multiple values with whitespace " ".
+        #* Begin line with "exclude=" to change to exclude filter, otherwise defaults to "most include" filter. Example: disks_filter="exclude=/boot /home/user".
+        disks_filter = ""
+
+        #* Show graphs instead of meters for memory values.
+        mem_graphs = True
+
+        #* Show mem box below net box instead of above.
+        mem_below_net = False
+
+        #* Count ZFS ARC in cached and available memory.
+        zfs_arc_cached = True
+
+        #* If swap memory should be shown in memory box.
+        show_swap = True
+
+        #* Show swap as a disk, ignores show_swap value above, inserts itself after first disk.
+        swap_disk = True
+
+        #* If mem box should be split to also show disks info.
+        show_disks = True
+
+        #* Filter out non physical disks. Set this to False to include network disks, RAM disks and similar.
+        only_physical = True
+
+        #* Read disks list from /etc/fstab. This also disables only_physical.
+        use_fstab = True
+
+        #* Setting this to True will hide all datasets, and only show ZFS pools. (IO stats will be calculated per-pool)
+        zfs_hide_datasets = False
+
+        #* Set to true to show available disk space for privileged users.
+        disk_free_priv = False
+
+        #* Toggles if io activity % (disk busy time) should be shown in regular disk usage view.
+        show_io_stat = True
+
+        #* Toggles io mode for disks, showing big graphs for disk read/write speeds.
+        io_mode = True
+
+        #* Set to True to show combined read/write io graphs in io mode.
+        io_graph_combined = False
+
+        #* Set the top speed for the io graphs in MiB/s (100 by default), use format "mountpoint:speed" separate disks with whitespace " ".
+        #* Example: "/mnt/media:100 /:20 /boot:1".
+        io_graph_speeds = ""
+
+        #* Set fixed values for network graphs in Mebibits. Is only used if net_auto is also set to False.
+        net_download = 100
+
+        net_upload = 100
+
+        #* Use network graphs auto rescaling mode, ignores any values set above and rescales down to 10 Kibibytes at the lowest.
+        net_auto = True
+
+        #* Sync the auto scaling for download and upload to whichever currently has the highest scale.
+        net_sync = True
+
+        #* Starts with the Network Interface specified here.
+        net_iface = ""
+
+        #* Show battery stats in top right if battery is present.
+        show_battery = False
+
+        #* Which battery to use if multiple are present. "Auto" for auto detection.
+        selected_battery = "Auto"
+
+        #* Show power stats of battery next to charge indicator.
+        show_battery_watts = True
+
+        #* Set loglevel for "~/.config/btop/btop.log" levels are: "ERROR" "WARNING" "INFO" "DEBUG".
+        #* The level set includes all lower levels, i.e. "DEBUG" will show all logging info.
+        log_level = "WARNING"
+
+        #* Measure PCIe throughput on NVIDIA cards, may impact performance on certain cards.
+        nvml_measure_pcie_speeds = True
+
+        #* Horizontally mirror the GPU graph.
+        gpu_mirror_graph = True
+
+        #* Custom gpu0 model name, empty string to disable.
+        custom_gpu_name0 = ""
+
+        #* Custom gpu1 model name, empty string to disable.
+        custom_gpu_name1 = ""
+
+        #* Custom gpu2 model name, empty string to disable.
+        custom_gpu_name2 = ""
+
+        #* Custom gpu3 model name, empty string to disable.
+        custom_gpu_name3 = ""
+
+        #* Custom gpu4 model name, empty string to disable.
+        custom_gpu_name4 = ""
+
+        #* Custom gpu5 model name, empty string to disable.
+        custom_gpu_name5 = ""
+      '';
+    };
+
+    xdg.configFile."btop/themes/nixos.theme" = {
+      enable = true;
+      text = with colors; ''
+        # Main background, empty for terminal default, need to be empty if you want transparent background
+        theme[main_bg]="#${base00}"
+
+        # Main text color
+        theme[main_fg]="#${base05}"
+
+        # Title color for boxes
+        theme[title]="#${base05}"
+
+        # Highlight color for keyboard shortcuts
+        theme[hi_fg]="#${base0D}"
+
+        # Background color of selected item in processes box
+        theme[selected_bg]="#${base03}"
+
+        # Foreground color of selected item in processes box
+        theme[selected_fg]="#${base0D}"
+
+        # Color of inactive/disabled text
+        theme[inactive_fg]="#8c8fa1"
+
+        # Color of text appearing on top of graphs, i.e uptime and current network graph scaling
+        theme[graph_text]="#${base06}"
+
+        # Background color of the percentage meters
+        theme[meter_bg]="#${base03}"
+
+        # Misc colors for processes box including mini cpu graphs, details memory graph and details status text
+        theme[proc_misc]="#${base06}"
+
+        # CPU, Memory, Network, Proc box outline colors
+        theme[cpu_box]="#${base0E}" #Mauve
+        theme[mem_box]="#${base0B}" #Green
+        theme[net_box]="#e64553" #Maroon
+        theme[proc_box]="#${colors.base0D}" #Blue
+
+        # Box divider line and small boxes line color
+        theme[div_line]="#9ca0b0"
+
+        # Temperature graph color (Green -> Yellow -> Red)
+        theme[temp_start]="#${base0B}"
+        theme[temp_mid]="#${base0A}"
+        theme[temp_end]="#${base08}"
+
+        # CPU graph colors (Teal -> Lavender)
+        theme[cpu_start]="#${base0C}"
+        theme[cpu_mid]="#209fb5"
+        theme[cpu_end]="#${base07}"
+
+        # Mem/Disk free meter (Mauve -> Lavender -> Blue)
+        theme[free_start]="#${base0E}"
+        theme[free_mid]="#${base07}"
+        theme[free_end]="#${base0D}"
+
+        # Mem/Disk cached meter (Sapphire -> Lavender)
+        theme[cached_start]="#209fb5"
+        theme[cached_mid]="#${base0D}"
+        theme[cached_end]="#${base07}"
+
+        # Mem/Disk available meter (Peach -> Red)
+        theme[available_start]="#${base09}"
+        theme[available_mid]="#e64553"
+        theme[available_end]="#${base08}"
+
+        # Mem/Disk used meter (Green -> Sky)
+        theme[used_start]="#${base0B}"
+        theme[used_mid]="#${base0C}"
+        theme[used_end]="#04a5e5"
+
+        # Download graph colors (Peach -> Red)
+        theme[download_start]="#${base09}"
+        theme[download_mid]="#e64553"
+        theme[download_end]="#${base08}"
+
+        # Upload graph colors (Green -> Sky)
+        theme[upload_start]="#${base0B}"
+        theme[upload_mid]="#${base0C}"
+        theme[upload_end]="#04a5e5"
+
+        # Process box color gradient for threads, mem and cpu usage (Sapphire -> Mauve)
+        theme[process_start]="#209fb5"
+        theme[process_mid]="#${base07}"
+        theme[process_end]="#${base0E}"
+      '';
+    };
+
+    modules.shell.aliases = {
+      top = "btop";
+    };
+  };
+}

unorganized/user-modules/default.nix

@@ -0,0 +1,42 @@
+{
+  ...
+}:
+
+{
+  imports = [
+    # Import all modules
+    ./bluetuith/default.nix
+    ./browser/default.nix
+    ./btop/default.nix
+    ./desktop/default.nix
+    ./development/default.nix
+    ./discord/default.nix
+    ./eduvpn/default.nix
+    ./feishin/default.nix
+    ./fontconfig/default.nix
+    ./gaming/default.nix
+    ./git/default.nix
+    ./keyring/default.nix
+    ./mako/default.nix
+    ./neovim/default.nix
+    ./obsidian/default.nix
+    ./rofi/default.nix
+    ./rofi/rofi-rbw.nix
+    ./scripts/default.nix
+    ./shell/default.nix
+    ./shell/bash.nix
+    ./shell/fish.nix
+    ./spotify/default.nix
+    ./terminal/default.nix
+    ./terminal/foot/default.nix
+    ./vscode/default.nix
+    ./whatsapp/default.nix
+    ./wprs/default.nix
+    ./winbox/default.nix
+    ./xpra/default.nix
+    ./zathura/default.nix
+
+    # Import unfree helper
+    ../modules/unfree/default.nix
+  ];
+}

unorganized/user-modules/desktop/custom/bar/waybar.nix

@@ -0,0 +1,164 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.waybar;
+  theme = config.desktop.theming;
+  colors = theme.colors;
+in
+{
+  options.modules.waybar = {
+    enable = mkEnableOption "waybar";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      pulsemixer
+      playerctl
+      networkmanagerapplet # TODO: Move
+    ];
+
+    modules.desktop.reloadScript = ''
+      # if ${pkgs.procps}/bin/pgrep waybar; then
+      #   ${pkgs.procps}/bin/pkill waybar
+      # fi
+      ${pkgs.waybar}/bin/waybar &
+    '';
+
+    programs.waybar = {
+      enable = true;
+      systemd.enable = false;
+      settings = {
+        mainBar = {
+          layer = "top";
+          spacing = 16;
+          modules-left = [ "river/tags" ];
+          modules-center = [
+            #"river/window"
+            "mpris"
+          ];
+          modules-right = [
+            "tray"
+            "bluetooth"
+            "network"
+            "pulseaudio"
+            "battery"
+            "clock"
+          ];
+          "river/window" = {
+            max-length = 50;
+          };
+          "river/tags" = {
+            tag-labels = [
+              "一"
+              "二"
+              "三"
+              "四"
+              "五"
+              "六"
+              "七"
+              "八"
+              "九"
+            ];
+            disable-click = false;
+          };
+          network = {
+            tooltip = false;
+            on-click = "wpa_gui";
+            format-wifi = "直 {essid}"; # Spacing achieved using "Thin Space"
+            format-ethernet = "TODO";
+            format-disconnected = "睊";
+          };
+          pulseaudio = {
+            tooltip = false;
+            format = "{icon}   {volume}%"; # Spacing achieved using "Thin Space"
+            #format-muted = "";
+            format-muted = "{icon}  --%"; # Spacing achieved using "Thin Space"
+            format-icons = {
+              #headphone = "";
+              #default = [ "" "" ];
+              headphone = "";
+              headphone-muted = "";
+              default = [
+                ""
+                ""
+                ""
+              ];
+            };
+          };
+          battery = {
+            format = "{icon} {capacity}%"; # Spacing achieved using "Thin Space"
+            format-charging = " {capacity}%"; # Spacing achieved using "Thin Space"
+            #format-icons = [ "󰂎" "󰁺" "󰁻" "󰁼" "󰁽" "󰁾" "󰁿" "󰂀" "󰂁" "󰂂" "󰁹" ];
+            format-icons = [
+              ""
+              ""
+              ""
+              ""
+              ""
+              ""
+              ""
+              ""
+              ""
+              ""
+              ""
+            ];
+            interval = 1;
+          };
+          clock = {
+            #format = "󰅐 {:%H:%M}";
+            #format = "   {:%H:%M}"; # Spacing achieved using "Thin Space"
+            format = "{:%H:%M}";
+          };
+          mpris = {
+            format = "{dynamic}";
+            tooltip-format = "";
+            interval = 1;
+          };
+          bluetooth = {
+            tooltip = false;
+            format = "  {status}"; # Spacing achieved using "Thin Space"
+            format-connected = "  {device_alias}"; # Spacing achieved using "Thin Space"
+          };
+        };
+      };
+      # TODO: Replace base03 color with named color
+      style = ''
+        window#waybar {
+          color: #${colors.fg};
+          background-color: #${colors.bg};
+          border-style: none none solid none;
+          border-width: ${toString theme.layout.borderSize}px;
+          border-color: #${colors.border-unfocused};
+          font-size: 12px;
+          font-family: "${theme.fonts.monospace.name}";
+        }
+
+        .modules-right {
+          margin: 0 8px 0 0;
+        }
+
+        #tags button {
+          color: #${theme.schemeColors.base03};
+          padding: 0 5px 1px 5px;
+          border-radius: 0;
+          font-size: 16px;
+          font-family: "wenquanyi bitmap song";
+        }
+
+        #tags button.occupied {
+          color: #${colors.fg};
+        }
+
+        #tags button.focused {
+          color: #${colors.accent};
+        }
+      '';
+    };
+  };
+}

unorganized/user-modules/desktop/custom/default.nix

@@ -0,0 +1,89 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.desktop;
+in
+{
+  imports = [
+    # Import desktop environment modules
+    ./bar/waybar.nix
+    ./lock-screen/waylock.nix
+    ./window-manager/river.nix
+  ];
+
+  options.modules.desktop = {
+    wayland = mkEnableOption "wayland";
+    # TODO: Find a nicer way to do this as this is also executed on startup
+    reloadScript = mkOption {
+      type = types.lines;
+      default = "";
+      description = "Shell script to execute after reload/rebuild.";
+    };
+    decorations = mkOption {
+      type = types.nullOr (
+        types.enum [
+          "csd"
+          "ssd"
+        ]
+      );
+      default = null;
+      description = "Window decorations to use.";
+    };
+  };
+
+  config = mkIf config.desktop.enable (
+    lib.recursiveUpdate
+      {
+        # Ensure desktop related systemd services (xdg) have access to session variables.
+        systemd.user.sessionVariables = config.home.sessionVariables;
+
+        home.packages = optionals cfg.wayland (
+          with pkgs;
+          [
+            wl-clipboard
+            wtype
+            grim
+            slurp
+          ]
+        );
+
+        home.activation = {
+          customReloadScript = lib.hm.dag.entryAfter [ "writeBoundary" ] (
+            ''
+              #!${pkgs.bash}/bin/bash
+            ''
+            + cfg.reloadScript
+          );
+        };
+
+        # home.file.".initrc" = {
+        #   enable = true;
+        #   executable = true;
+        #   text =
+        #     ''
+        #       #!${pkgs.bash}/bin/bash
+
+        #     ''
+        #     + cfg.initScript;
+        # };
+      }
+      (
+        # TODO: Move to dedicated module within desktop or maybe theming?
+        # if cfg.decorations == null then
+        #   { }
+        # else
+        #   {
+        #     csd = { };
+        #     ssd = { };
+        #   }
+        #   ."${cfg.decorations}"
+        { }
+      )
+  );
+}

unorganized/user-modules/desktop/custom/lock-screen/waylock.nix

@@ -0,0 +1,20 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.waylock;
+in
+{
+  options.modules.waylock = {
+    enable = mkEnableOption "waylock";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = (with pkgs; [ waylock ]);
+  };
+}

unorganized/user-modules/desktop/custom/window-manager/river.nix

@@ -0,0 +1,268 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.modules.river;
+in
+{
+  options.modules.river.enable = lib.mkEnableOption "river";
+
+  # osConfig = lib.mkIf cfg.enable {
+  #   programs.river.enable = true;
+  # };
+
+  config = lib.mkIf cfg.enable {
+    # Set desktop type to wayland
+    modules.desktop.wayland = true;
+
+    # TODO: Move elsewhere and make keybindings more configurable
+    modules.rofi.enable = true;
+
+    # TODO: Move elsewhere
+    home.packages = with pkgs; [
+      brightnessctl
+      river-filtile
+      # owm
+
+      udiskie # TODO: Move to USB module
+    ];
+
+    # Change desktop to execute river
+    desktop.initScript = ''
+      ${pkgs.river}/bin/river
+    '';
+
+    desktop.session.type = "wayland";
+    desktop.session.desktop = "river";
+
+    # TODO: Fix this
+    # modules.desktop.reloadScript = ''
+    #   ${pkgs.river}/bin/riverctl background-color 0x${config.theming.colors.bg}
+    # '';
+
+    # Update background after rebuild
+    # home.activation = {
+    #   river = lib.hm.dag.entryBetween [ "reloadSystemd" ] [ "installPackages" ] ''
+    #     # Close waybar
+    #     PATH="${pkgs.procps}/bin:$PATH" $DRY_RUN_CMD pkill waybar
+
+    #     # Kill rivertile
+    #     PATH="${pkgs.procps}/bin:$PATH" $DRY_RUN_CMD pkill rivertile
+
+    #     # Kill glpaper
+    #     PATH="${pkgs.procps}/bin:$PATH" $DRY_RUN_CMD pkill glpaper
+
+    #     # Restart river
+    #     PATH="${pkgs.river}/bin:${pkgs.systemd}/bin:${pkgs.waybar}/bin:$PATH" $DRY_RUN_CMD ~/.config/river/init
+    #   '';
+    # };
+
+    # River setup
+    wayland.windowManager.river = {
+      enable = true;
+      xwayland.enable = false;
+      systemd.enable = true;
+      settings =
+        let
+          layout = "filtile";
+          layoutOptions = "-outer-padding ${toString config.desktop.theming.layout.windowPadding} -view-padding ${toString config.desktop.theming.layout.windowPadding} -main-ratio 0.5";
+          modes = [
+            "normal"
+            "locked"
+          ];
+          tags = [
+            1
+            2
+            3
+            4
+            5
+            6
+            7
+            8
+            9
+          ];
+          waylockOptions = "-init-color 0x${colors.bg} -input-color 0x${colors.border-focused} -fail-color 0x${colors.bg}";
+
+          colors = config.desktop.theming.colors;
+
+          # Quick pow function
+          pow2 = power: if power != 0 then 2 * (pow2 (power - 1)) else 1;
+
+          # Modifiers
+          main = "Super";
+          ssm = "Super+Shift";
+          sas = "Super+Alt+Shift";
+          sam = "Super+Alt";
+          scm = "Super+Control";
+          scam = "Super+Control+Alt";
+          ssc = "Super+Shift+Control";
+        in
+        {
+          default-layout = "${layout}";
+          set-repeat = "50 300";
+          xcursor-theme = "BreezeX-RosePine-Linux 24";
+          keyboard-layout = "-options \"caps:escape\" us";
+
+          border-width = toString config.desktop.theming.layout.borderSize;
+          background-color = "0x${colors.bg}";
+          border-color-focused = "0x${colors.fg}";
+          border-color-unfocused = "0x${colors.border-unfocused}"; # TODO: Change to use named color;
+          border-color-urgent = "0x${colors.fg}";
+
+          # TODO: Make a desktop options for DE applications
+          spawn = [
+            "\"${layout} ${layoutOptions}\""
+            "waybar" # TODO: Decouple
+            # TODO: Generic background options
+            # "\"glpaper eDP-1 ${toString config.modules.glpaper.shader}\""
+            "udiskie"
+            # TODO: Should this be part of the keyring configuration directly?
+            # "\"gnome-keyring-daemon --replace --components=pkcs11,secrets,ssh\""
+            "wpaperd"
+          ];
+          map = (
+            lib.attrsets.recursiveUpdate
+              {
+                "-repeat".normal = {
+                  # Basic utilities
+                  "${main} Q" = "close";
+                  "${ssm} Return" = "spawn foot";
+
+                  # Window focus
+                  "${main} J" = "focus-view next";
+                  "${main} K" = "focus-view previous";
+
+                  # Swap windows
+                  "${ssm} J" = "swap next";
+                  "${ssm} K" = "swap previous";
+                  "${main} Return" = "zoom";
+
+                  # Main ratio
+                  "${main} H" = "send-layout-cmd ${layout} 'main-ratio -0.05'";
+                  "${main} L" = "send-layout-cmd ${layout} 'main-ratio +0.05'";
+
+                  # Main count
+                  "${ssm} H" = "send-layout-cmd ${layout} 'main-count +1'";
+                  "${ssm} L" = "send-layout-cmd ${layout} 'main-count -1'";
+
+                  # Move floating windows
+                  "${sam} H" = "move left 100";
+                  "${sam} J" = "move down 100";
+                  "${sam} K" = "move up 100";
+                  "${sam} L" = "move right 100";
+
+                  # Resize floating windows
+                  "${sas} H" = "resize horizontal -100";
+                  "${sas} J" = "resize vertical 100";
+                  "${sas} K" = "resize vertical -100";
+                  "${sas} L" = "resize horizontal 100";
+
+                  # Toggle modes
+                  "${main} Space" = "toggle-float";
+                  "${main} F" = "toggle-fullscreen";
+                };
+                normal =
+                  {
+                    # Basic utilities
+                    "${ssm} E" = "exit";
+                    "${main} X " = "spawn \"waylock -fork-on-lock ${waylockOptions}\"";
+                    "${main} P" = "spawn \"rofi -show drun\"";
+                    "${ssm} P" = "spawn rofi-rbw";
+                    "${main} S" =
+                      "spawn \"grim -g \\\"\\\$(slurp)\\\" ~/Images/Screenshots/\\\$(date +'%s_grim.png')\"";
+
+                    # Tags
+                    "${main} 0" = "set-focused-tags ${toString (pow2 32 - 1)}";
+                    "${ssm} 0" = "set-view-tags ${toString (pow2 32 - 1)}";
+
+                    # Orientation
+                    "${main} Up" = "send-layout-cmd ${layout} \"main-location top\"";
+                    "${main} Right" = "send-layout-cmd ${layout} \"main-location right\"";
+                    "${main} Down" = "send-layout-cmd ${layout} \"main-location bottom\"";
+                    "${main} Left" = "send-layout-cmd ${layout} \"main-location left\"";
+
+                    # Snap floating windows
+                    "${scam} H" = "snap left";
+                    "${scam} J" = "snap down";
+                    "${scam} K" = "snap up";
+                    "${scam} L" = "snap right";
+                  }
+                  // builtins.listToAttrs (
+                    builtins.concatLists (
+                      map (tag: [
+                        {
+                          name = "${main} ${toString tag}";
+                          value = "set-focused-tags ${toString (pow2 (tag - 1))}";
+                        }
+                        {
+                          name = "${ssm} ${toString tag}";
+                          value = "set-view-tags ${toString (pow2 (tag - 1))}";
+                        }
+                        {
+                          name = "${scm} ${toString tag}";
+                          value = "toggle-focused-tags ${toString (pow2 (tag - 1))}";
+                        }
+                        {
+                          name = "${ssc} ${toString tag}";
+                          value = "toggle-view-tags ${toString (pow2 (tag - 1))}";
+                        }
+                      ]) tags
+                    )
+                  );
+              }
+              (
+                builtins.listToAttrs (
+                  map (mode: {
+                    name = "${mode}";
+                    value = {
+                      # Control volume
+                      "None XF86AudioRaiseVolume" = "spawn \"pulsemixer --change-volume +5\"";
+                      "None XF86AudioLowerVolume" = "spawn \"pulsemixer --change-volume -5\"";
+                      "None XF86AudioMute" = "spawn \"pulsemixer --toggle-mute\"";
+
+                      # Control brightness
+                      "None XF86MonBrightnessUp" = "spawn \"brightnessctl set +5%\"";
+                      "None XF86MonBrightnessDown" = "spawn \"brightnessctl set 5%-\"";
+
+                      # Control music playback
+                      "None XF86Messenger" = "spawn \"playerctl previous\"";
+                      "None XF86Go" = "spawn \"playerctl play-pause\"";
+                      "None Cancel" = "spawn \"playerctl next\"";
+                    };
+                  }) modes
+                )
+              )
+          );
+          map-pointer = {
+            normal = {
+              "${main} BTN_LEFT" = "move-view";
+              "${main} BTN_RIGHT" = "resize-view";
+              "${main} BTN_MIDDLE" = "toggle-float";
+            };
+          };
+          input = {
+            "'*'" = {
+              accel-profile = "adaptive";
+              pointer-accel = "0.5";
+              scroll-factor = "0.8";
+            };
+            "'*Synaptics*'" = {
+              natural-scroll = "enabled";
+            };
+          };
+          rule-add = {
+            "-app-id" = {
+              "'bar'" = "csd";
+              "'*'" = "ssd";
+              "'wpa_gui'" = "float";
+              "'Xpra'" = "float";
+            };
+          };
+        };
+    };
+  };
+}

unorganized/user-modules/desktop/default.nix

@@ -0,0 +1,127 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  # Desktop configuration module
+  desktopConfigurationModule = types.submodule {
+    options = {
+      name = mkOption {
+        type = types.str;
+        description = "Desktop environment name.";
+      };
+      type = mkOption {
+        type = types.enum [
+          "custom"
+          "gnome"
+        ];
+        description = "Desktop environment type.";
+      };
+      config = mkOption {
+        type = types.attrs;
+        default = { };
+        description = "Desktop environment configuration";
+      };
+      extraConfig = mkOption {
+        type = types.attrs;
+        default = { };
+        description = "Extra configuration for the configured desktop environment";
+      };
+    };
+  };
+
+  customBuilder =
+    config:
+    recursiveUpdate {
+      desktop.name = config.name;
+    } config.extraConfig;
+
+  # Environment builders
+  environmentBuilders = {
+    custom = customBuilder;
+  };
+
+  cfg = config.desktop;
+in
+{
+  imports = [
+    ./custom/default.nix
+    ./theming/default.nix
+  ];
+
+  options.desktop = {
+    enable = mkEnableOption "desktop";
+    name = mkOption {
+      type = types.str;
+      default = "Shell";
+      description = "Desktop configuration name.";
+    };
+    initScript = mkOption {
+      type = types.lines;
+      default = ''
+        ${pkgs.ncurses}/bin/clear
+        ${pkgs.bashInteractive}/bin/bash
+      '';
+      description = "Bash script to execute after logging in.";
+    };
+    session = {
+      type = mkOption {
+        type = types.enum [
+          "wayland"
+          "x11"
+          "tty"
+        ];
+        default = "tty";
+        description = "Session type.";
+      };
+      desktop = mkOption {
+        type = types.str;
+        default = "tty";
+        description = "Desktop environment name.";
+      };
+    };
+    environments = mkOption {
+      type = types.attrsOf desktopConfigurationModule;
+      default = { };
+      description = "Desktop environments. Every environment will be built as a specialization.";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    specialisation = mapAttrs (name: value: {
+      configuration = (environmentBuilders."${value.type}" value);
+    }) cfg.environments;
+
+    # Create session files
+    home.extraBuilderCommands = ''
+      mkdir $out/session
+      echo "${cfg.name}" > $out/session/name
+      ln -s ${
+        pkgs.writeTextFile {
+          name = "desktop-init";
+          text =
+            ''
+              #!${pkgs.bash}/bin/bash
+
+            ''
+            + cfg.initScript;
+          executable = true;
+        }
+      } $out/session/init
+      ln -s ${
+        pkgs.writeTextFile {
+          name = "session-env";
+          text = ''
+            XDG_SESSION_TYPE=${cfg.session.type}
+            XDG_CURRENT_DESKTOP=${cfg.session.desktop}
+            XDG_SESSION_DESKTOP=${cfg.session.desktop}
+          '';
+        }
+      } $out/session/env
+    '';
+  };
+}

unorganized/user-modules/desktop/systemwide.nix

@@ -0,0 +1,8 @@
+{
+  waylock = {
+    security.pam.services.waylock = { };
+  };
+  river = {
+    programs.river.enable = true;
+  };
+}

unorganized/user-modules/desktop/theming/background.nix

@@ -0,0 +1,133 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming.background;
+in
+{
+  options.desktop.theming.background = {
+    image = {
+      url = mkOption {
+        type = types.str;
+        default = "https://raw.githubusercontent.com/dharmx/walls/refs/heads/main/digital/a_drawing_of_a_spider_on_a_white_surface.png";
+        description = "URL to the background image.";
+      };
+      hash = mkOption {
+        type = types.str;
+        default = "sha256-eCEjM7R9yeHNhZZtvHjrgkfwT25JA7FeMoVwnQ887CQ=";
+        description = "SHA256 hash of the background image.";
+      };
+    };
+    themed = mkEnableOption "themed background";
+    inverted = mkEnableOption "invert background";
+  };
+
+  config =
+    with pkgs;
+    let
+      src = pkgs.fetchurl {
+        url = cfg.image.url;
+        hash = cfg.image.hash;
+      };
+
+      theme = writeTextFile {
+        name = "gowall-theme";
+        text = builtins.toJSON {
+          name = "NixOS";
+          colors =
+            let
+              colors = config.desktop.theming.schemeColors;
+            in
+            [
+              "#${colors.base00}"
+              "#${colors.base01}"
+              "#${colors.base02}"
+              "#${colors.base03}"
+              "#${colors.base04}"
+              "#${colors.base05}"
+              "#${colors.base06}"
+              "#${colors.base07}"
+              "#${colors.base08}"
+              "#${colors.base09}"
+              "#${colors.base0A}"
+              "#${colors.base0B}"
+              "#${colors.base0C}"
+              "#${colors.base0D}"
+              "#${colors.base0E}"
+              "#${colors.base0F}"
+            ];
+        };
+        executable = true;
+      };
+
+      fileExtension =
+        name:
+        let
+          parts = splitString "." name;
+        in
+        if length parts > 1 then lists.last parts else "";
+
+      fileName =
+        name:
+        let
+          parts = splitString "/" name;
+        in
+        if length parts > 1 then lists.last parts else name;
+
+      image = fileName cfg.image.url;
+
+      background-themed = stdenv.mkDerivation {
+        name = "background-themed-1.0.0";
+        src = src;
+
+        buildInputs = [
+          gowall
+          imagemagick
+          (writeShellScriptBin "xdg-open" "")
+          tree
+        ];
+
+        unpackPhase = ''
+          cp ${src} ./${image}
+          chmod u+w ./${image}
+        '';
+
+        buildPhase = ''
+          ${optionalString cfg.inverted ''
+            convert ./${image} -channel RGB -negate ./${image}
+          ''}
+          ${optionalString cfg.themed ''
+            cp ${theme} ./theme.json
+
+            export HOME=$PWD
+
+            gowall convert ./${image} --output themed -t ./theme.json
+            tree
+            mv ./themed/*.* ./
+          ''}
+          mv ./${image} themed.${fileExtension image}
+          ${optionalString (fileExtension image != "png") ''
+            mogrify -format png themed.*
+          ''}
+        '';
+
+        installPhase = ''
+          install -Dm644 -t $out themed.png
+        '';
+      };
+    in
+    {
+      services.wpaperd = {
+        enable = true;
+        settings.default = {
+          path = "${background-themed}/";
+          mode = "center";
+        };
+      };
+    };
+}

unorganized/user-modules/desktop/theming/colors.nix

@@ -0,0 +1,159 @@
+{
+  pkgs,
+  lib,
+  config,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming;
+in
+{
+  imports = [
+    # Import all themes
+    ./themes/catppuccin.nix
+    ./themes/gruvbox.nix
+    ./themes/oxocarbon.nix
+    ./themes/papercolor.nix
+    ./themes/sakura.nix
+    ./themes/nord.nix
+  ];
+
+  options.desktop.theming =
+    let
+      colors = config.desktop.theming.schemeColors;
+    in
+    {
+      darkMode = mkOption {
+        type = types.bool;
+        default = false;
+        example = true;
+        description = "Whether the app should use dark mode.";
+      };
+
+      colorScheme = mkOption {
+        type = types.nullOr types.str;
+        default = "${pkgs.base16-schemes}/share/themes/catppuccin-mocha.yaml";
+        description = "Base 16 color scheme to use for styling. See stylix documentation for more information.";
+      };
+
+      schemeColors = mkOption {
+        type = types.attrsOf types.anything;
+        default = config.lib.stylix.colors;
+        description = "Generated colors from scheme";
+      };
+
+      colors = {
+        bg = mkOption {
+          type = types.str;
+          default = colors.base00;
+        };
+        fg = mkOption {
+          type = types.str;
+          default = colors.base05;
+        };
+        bg-status = mkOption {
+          type = types.str;
+          default = colors.base01;
+        };
+        fg-status = mkOption {
+          type = types.str;
+          default = colors.base04;
+        };
+        bg-selection = mkOption {
+          type = types.str;
+          default = colors.base02;
+        };
+        bg-highlight = mkOption {
+          type = types.str;
+          default = colors.base03;
+        };
+        fg-search = mkOption {
+          type = types.str;
+          default = colors.base0A;
+        };
+        accent = mkOption {
+          type = types.str;
+          default = colors.base0E;
+        };
+        border-focused = mkOption {
+          type = types.str;
+          default = cfg.colors.fg;
+        };
+        border-unfocused = mkOption {
+          type = types.str;
+          default = cfg.colors.bg-selection;
+        };
+      };
+
+      colorsCSS = mkOption {
+        type = types.lines;
+        default =
+          ":root {\n"
+          + concatStrings (
+            map (color: "  --nix-color-${color.name}: #${color.value};\n") (attrsToList cfg.colors)
+          )
+          + "}\n\n";
+        description = "Colors as css variables";
+      };
+    };
+
+  config = {
+    # Configure gnome theme
+    dconf.settings = mkIf config.desktop.enable {
+      "org/gnome/desktop/interface" = {
+        color-scheme = if cfg.darkMode then "prefer-dark" else "prefer-light";
+      };
+    };
+
+    # Configure qt theme
+    qt = mkIf config.desktop.enable {
+      enable = true;
+      platformTheme.name = "gtk";
+      style = {
+        name = if cfg.darkMode then "adwaita-dark" else "adwaita-light";
+        package = pkgs.adwaita-qt;
+      };
+    };
+
+    # Configure gtk theme
+    gtk = mkIf config.desktop.enable {
+      enable = true;
+      theme = {
+        name = if cfg.darkMode then "Adwaita-dark" else "Adwaita-light";
+        package = pkgs.gnome-themes-extra;
+      };
+    };
+
+    # TODO: This should just straight up not be here
+    programs.direnv = {
+      enable = true;
+      nix-direnv.enable = true;
+    };
+    modules.git.ignores = [
+      ".direnv"
+    ];
+
+    # Enable stylix
+    # TODO: Move to own module
+    stylix = {
+      enable = true;
+      autoEnable = false;
+
+      targets = {
+        foot.enable = true;
+        nixvim.enable = true;
+        qutebrowser.enable = true;
+        vscode = {
+          enable = true;
+          profileNames = [ "default" ];
+        };
+        zathura.enable = true;
+      };
+
+      base16Scheme = cfg.colorScheme;
+      polarity = if cfg.darkMode then "dark" else "light";
+    };
+  };
+}

unorganized/user-modules/desktop/theming/default.nix

@@ -0,0 +1,241 @@
+{
+  pkgs,
+  lib,
+  config,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming;
+
+  # Font module type
+  fontModule = types.submodule {
+    options = {
+      name = mkOption {
+        type = types.str;
+        description = "Font family name.";
+      };
+      package = mkOption {
+        type = types.anything;
+        description = "Font package";
+      };
+      recommendedSize = mkOption {
+        type = types.nullOr types.int;
+        default = null;
+        description = "Recommended size for displaying this font.";
+      };
+      fallbackFonts = mkOption {
+        type = types.listOf types.str;
+        default = [ ];
+        description = "Fallback fonts for specified font.";
+      };
+    };
+  };
+
+  fontModules = [
+    # Import all fonts
+    ./fonts/adwaita-mono.nix
+    ./fonts/adwaita-sans.nix
+    ./fonts/cozette-vector.nix
+    ./fonts/cozette.nix
+    ./fonts/dejavu-sans.nix
+    ./fonts/dejavu-serif.nix
+    ./fonts/dina.nix
+    ./fonts/fira-code.nix
+    ./fonts/nerd-fonts-symbols.nix
+    ./fonts/noto-color-emoji.nix
+    ./fonts/wqy-bitmapsong.nix
+    ./fonts/wqy-microhei-mono.nix
+    ./fonts/wqy-microhei.nix
+    ./fonts/wqy-zenhei-mono.nix
+    ./fonts/wqy-zenhei-sharp.nix
+    ./fonts/wqy-zenhei.nix
+  ];
+
+  # Gather enabled fonts.
+  enabledFonts = [
+    cfg.fonts.serif.name
+    cfg.fonts.sansSerif.name
+    cfg.fonts.monospace.name
+    cfg.fonts.emoji.name
+  ] ++ map (font: font.name) cfg.fonts.extraFonts;
+
+  # Flatten dependencies of fonts
+  fontPackages =
+    converge
+      (
+        fonts:
+        listToAttrs (
+          map
+            (font: {
+              name = font;
+              value = true;
+            })
+            (
+              flatten (map (font: [ font.name ] ++ cfg.fonts.pkgs.${font.name}.fallbackFonts) (attrsToList fonts))
+            )
+        )
+      )
+      (
+        listToAttrs (
+          map (font: {
+            name = font;
+            value = true;
+          }) enabledFonts
+        )
+      );
+
+  # Convert set of fonts to list of packages
+  fontNameList = map (font: font.name) (attrsToList fontPackages);
+  fontPackageList = map (font: cfg.fonts.pkgs.${font}.package) fontNameList;
+in
+{
+  imports = [
+    ./background.nix
+    ./colors.nix
+  ];
+
+  options.desktop.theming = {
+    layout = {
+      borderRadius = mkOption {
+        type = types.int;
+        default = 0;
+        description = "Border radius of windows.";
+      };
+
+      borderSize = mkOption {
+        type = types.int;
+        default = 1;
+        description = "Size of borders used throughout UI.";
+      };
+
+      windowPadding = mkOption {
+        type = types.int;
+        default = 2;
+        description = "Margin of each window, actual space between windows will be twice this number.";
+      };
+    };
+
+    fonts = {
+      pkgs = mkOption {
+        type = types.attrsOf fontModule;
+        default = builtins.listToAttrs (
+          map (module: {
+            name = module.name;
+            value = module;
+          }) (map (module: (import module) { inherit lib config pkgs; }) fontModules)
+        );
+        description = "All available font modules.";
+      };
+
+      installed = mkOption {
+        type = types.listOf types.str;
+        default = fontNameList;
+        description = "List of installed fonts.";
+      };
+
+      serif = mkOption {
+        type = fontModule;
+        description = "Default serif font";
+      };
+
+      sansSerif = mkOption {
+        type = fontModule;
+        description = "Default sansSerif font.";
+      };
+
+      monospace = mkOption {
+        type = fontModule;
+        description = "Default monospace font.";
+      };
+
+      emoji = mkOption {
+        type = fontModule;
+        description = "Default emoji font.";
+      };
+
+      interface = mkOption {
+        type = fontModule;
+        description = "Default emoji font.";
+      };
+
+      extraFonts = mkOption {
+        type = types.listOf fontModule;
+        default = [ ];
+        description = "Additional fonts to install.";
+      };
+    };
+  };
+
+  config = mkIf config.desktop.enable {
+    # Enable fontconfig
+    modules.fontconfig.enable = true;
+
+    # Install configured fonts
+    home.packages = fontPackageList;
+
+    # Configure gtk theme
+    gtk =
+      let
+        disableCSD = ''
+          headerbar.default-decoration {
+            margin-bottom: 50px;
+            margin-top: -100px;
+          }
+          window.csd,
+          window.csd decoration {
+            box-shadow: none;
+          }
+        '';
+      in
+      {
+        enable = true;
+        # TODO: Toggles
+        gtk3.extraCss = mkIf config.modules.river.enable disableCSD;
+        gtk4.extraCss = mkIf config.modules.river.enable disableCSD;
+      };
+
+    # TODO: Make cursors configurable using modules.
+    home.pointerCursor = {
+      gtk.enable = true;
+      name = lib.mkForce "BreezeX-RosePine-Linux";
+      package = lib.mkForce pkgs.rose-pine-cursor;
+      size = lib.mkForce 24;
+      x11 = {
+        defaultCursor = lib.mkForce "BreezeX-RosePine-Linux";
+        enable = true;
+      };
+    };
+
+    # Enable stylix
+    # TODO: Move to own module
+    stylix = {
+      fonts = {
+        serif = getAttrs [
+          "name"
+          "package"
+        ] cfg.fonts.serif;
+        sansSerif = getAttrs [
+          "name"
+          "package"
+        ] cfg.fonts.sansSerif;
+        monospace = getAttrs [
+          "name"
+          "package"
+        ] cfg.fonts.monospace;
+        emoji = getAttrs [
+          "name"
+          "package"
+        ] cfg.fonts.emoji;
+
+        sizes = {
+          applications = mkDefault cfg.fonts.serif.recommendedSize;
+          desktop = mkDefault cfg.fonts.monospace.recommendedSize; # TODO: See below
+          popups = mkDefault cfg.fonts.monospace.recommendedSize; # TODO: Add dedicated UI font
+          terminal = mkDefault cfg.fonts.monospace.recommendedSize;
+        };
+      };
+    };
+  };
+}

unorganized/user-modules/desktop/theming/fonts/adwaita-mono.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "Adwaita Mono";
+  package = pkgs.adwaita-fonts;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/adwaita-sans.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "Adwaita Sans";
+  package = pkgs.adwaita-fonts;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/cozette-vector.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "Cozette Vector";
+  package = pkgs.cozette;
+  recommendedSize = 9;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/cozette.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "Cozette";
+  package = pkgs.cozette;
+  recommendedSize = 9;
+  fallbackFonts = [ "Cozette Vector" ];
+}

unorganized/user-modules/desktop/theming/fonts/dejavu-sans.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "DejaVu Sans";
+  package = pkgs.dejavu_fonts;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/dejavu-serif.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "DejaVu Serif";
+  package = pkgs.dejavu_fonts;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/dina.nix

@@ -0,0 +1,12 @@
+{ pkgs, ... }:
+
+{
+  name = "Dina";
+  package = pkgs.dina-font;
+  recommendedSize = 9;
+  fallbackFonts = [
+    "Cozette"
+    "wenquanyi bitmap song"
+    "Symbols Nerd Font Mono"
+  ];
+}

unorganized/user-modules/desktop/theming/fonts/fira-code.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "Fira Code";
+  package = pkgs.fira-code;
+  recommendedSize = 12;
+  fallbackFonts = [ "Symbols Nerd Font Mono" ];
+}

unorganized/user-modules/desktop/theming/fonts/nerd-fonts-symbols.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "Symbols Nerd Font Mono";
+  package = pkgs.nerd-fonts.symbols-only;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/noto-color-emoji.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "Noto Color Emoji";
+  package = pkgs.noto-fonts-color-emoji;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/wqy-bitmapsong.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "wenquanyi bitmap song";
+  package = pkgs.wqy-bitmapsong;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/wqy-microhei-mono.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "WenQuanYi Micro Hei Mono";
+  package = pkgs.wqy-microhei;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/wqy-microhei.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "WenQuanYi Micro Hei";
+  package = pkgs.wqy-microhei;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/wqy-zenhei-mono.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "WenQuanYi Zen Hei Mono";
+  package = pkgs.wqy-zenhei;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/wqy-zenhei-sharp.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "WenQuanYi Zen Hei Sharp";
+  package = pkgs.wqy-zenhei;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/fonts/wqy-zenhei.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  name = "WenQuanYi Zen Hei";
+  package = pkgs.wqy-zenhei;
+  recommendedSize = 12;
+  fallbackFonts = [ ];
+}

unorganized/user-modules/desktop/theming/themes/catppuccin.nix

@@ -0,0 +1,33 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming.themes.catppuccin;
+in
+{
+  options = {
+    desktop.theming.themes.catppuccin = {
+      enable = mkEnableOption "catppuccin";
+      flavor = mkOption {
+        type = types.enum [
+          "latte"
+          "frappe"
+          "macchiato"
+          "mocha"
+        ];
+        default = "mocha";
+        description = "The flavor of catppuccin theme.";
+      };
+    };
+  };
+
+  config.desktop.theming = mkIf cfg.enable {
+    darkMode = (cfg.flavor != "latte");
+    colorScheme = "${pkgs.base16-schemes}/share/themes/catppuccin-${cfg.flavor}.yaml";
+  };
+}

unorganized/user-modules/desktop/theming/themes/gruvbox.nix

@@ -0,0 +1,34 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming.themes.gruvbox;
+  mode = if cfg.darkMode then "dark" else "light";
+in
+{
+  options = {
+    desktop.theming.themes.gruvbox = {
+      enable = mkEnableOption "gruvbox-hard";
+      darkMode = mkEnableOption "dark mode";
+      contrast = mkOption {
+        type = types.enum [
+          "hard"
+          "medium"
+          "soft"
+        ];
+        default = "hard";
+        description = "The contrast level of the theme.";
+      };
+    };
+  };
+
+  config.desktop.theming = mkIf cfg.enable {
+    darkMode = cfg.darkMode;
+    colorScheme = "${pkgs.base16-schemes}/share/themes/gruvbox-${mode}-${cfg.contrast}.yaml";
+  };
+}

unorganized/user-modules/desktop/theming/themes/nord.nix

@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming.themes.nord;
+  mode = if cfg.darkMode then "" else "-light";
+in
+{
+  options = {
+    desktop.theming.themes.nord = {
+      enable = mkEnableOption "nord";
+      darkMode = mkEnableOption "dark mode";
+    };
+  };
+
+  config.desktop.theming = mkIf cfg.enable {
+    darkMode = cfg.darkMode;
+    colorScheme = "${pkgs.base16-schemes}/share/themes/nord${mode}.yaml";
+  };
+}

unorganized/user-modules/desktop/theming/themes/oxocarbon.nix

@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming.themes.oxocarbon;
+  mode = if cfg.darkMode then "dark" else "light";
+in
+{
+  options = {
+    desktop.theming.themes.oxocarbon = {
+      enable = mkEnableOption "oxocarbon";
+      darkMode = mkEnableOption "dark mode";
+    };
+  };
+
+  config.desktop.theming = mkIf cfg.enable {
+    darkMode = cfg.darkMode;
+    colorScheme = "${pkgs.base16-schemes}/share/themes/oxocarbon-${mode}.yaml";
+  };
+}

unorganized/user-modules/desktop/theming/themes/papercolor.nix

@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming.themes.papercolor;
+  mode = if cfg.darkMode then "dark" else "light";
+in
+{
+  options = {
+    desktop.theming.themes.papercolor = {
+      enable = mkEnableOption "papercolor";
+      darkMode = mkEnableOption "dark mode";
+    };
+  };
+
+  config.desktop.theming = mkIf cfg.enable {
+    darkMode = cfg.darkMode;
+    colorScheme = "${pkgs.base16-schemes}/share/themes/papercolor-${mode}.yaml";
+  };
+}

unorganized/user-modules/desktop/theming/themes/sakura.nix

@@ -0,0 +1,23 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.desktop.theming.themes.sakura;
+in
+{
+  options = {
+    desktop.theming.themes.sakura = {
+      enable = mkEnableOption "sakura";
+    };
+  };
+
+  config.desktop.theming = mkIf cfg.enable {
+    darkMode = false;
+    colorScheme = "${pkgs.base16-schemes}/share/themes/sakura.yaml";
+  };
+}

unorganized/user-modules/development/default.nix

@@ -0,0 +1,19 @@
+{ ... }:
+
+{
+  imports = [
+    ./ide/mathematica.nix
+    ./ide/matlab.nix
+    # TODO: Move languages to make clear it is just IDE configuration
+    # Languages should be installed with devShells, however the IDE must be configured globally
+    ./language/cpp.nix
+    ./language/haskell.nix
+    ./language/js.nix
+    ./language/jupyter.nix
+    ./language/nix.nix
+    ./language/python.nix
+    ./language/rust.nix
+    ./language/tex.nix
+    ./utility/docker.nix
+  ];
+}

unorganized/user-modules/development/ide/mathematica.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.mathematica;
+
+  my-mathematica = pkgs.mathematica.override {
+    # TODO: Just use a generic name for the installer?
+    # source = ./Wolfram_14.2.1_LIN_Bndl.sh;
+  };
+in
+{
+  options.modules.mathematica = {
+    enable = mkEnableOption "mathematica";
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [
+      "mathematica"
+    ];
+
+    home.packages = [
+      my-mathematica
+    ];
+  };
+}

unorganized/user-modules/development/ide/matlab.nix

@@ -0,0 +1,26 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.matlab;
+in
+{
+  options.modules.matlab = {
+    enable = mkEnableOption "matlab";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      matlab
+    ];
+
+    home.sessionVariables = {
+      _JAVA_AWT_WM_NONREPARENTING = "1";
+    };
+  };
+}

unorganized/user-modules/development/language/cpp.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.cpp;
+in
+{
+  options.modules.cpp = {
+    enable = mkEnableOption "cpp";
+  };
+
+  config = mkIf cfg.enable {
+    # Allow unfree
+    modules.unfree.allowedPackages = [
+      "vscode-extension-ms-vscode-cpptools"
+    ];
+
+    # Gitignore additions
+    modules.git.ignores = [
+      ".ccls-cache"
+    ];
+
+    # Development packages
+    home.packages = with pkgs; [
+      gnumake
+      gcc
+    ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          ms-vscode.cpptools
+          ms-vscode.cmake-tools
+          ms-vscode.cpptools-extension-pack
+        ];
+
+        userSettings = {
+          # TODO: Add setting to set the compiler, it currently needs to be set for each workspace individually
+          # "C_Cpp.clang_format_fallbackStyle" = "{ BasedOnStyle: Google, IndentWidth: 4 }";
+        };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = {
+      plugins.lsp.servers.ccls.enable = true;
+    };
+  };
+}

unorganized/user-modules/development/language/haskell.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.haskell;
+in
+{
+  options.modules.haskell = {
+    enable = mkEnableOption "haskell";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = with pkgs; [
+      haskell.compiler.ghc948
+      (haskell-language-server.override { supportedGhcVersions = [ "948" ]; })
+    ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          haskell.haskell
+          justusadam.language-haskell
+        ];
+
+        userSettings = {
+          "[haskell]" = { };
+          # "haskell.formattingProvider" = "fourmolu";
+        };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = { };
+  };
+}

unorganized/user-modules/development/language/js.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.js;
+in
+{
+  options.modules.js = {
+    enable = mkEnableOption "js";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = with pkgs; [
+      nodejs
+      tailwindcss
+    ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          bradlc.vscode-tailwindcss
+        ];
+
+        userSettings = { };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = { };
+  };
+}

unorganized/user-modules/development/language/jupyter.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+# TODO: Move to a module for notebooks in general
+with lib;
+let
+  cfg = config.modules.jupyter;
+in
+{
+  options.modules.jupyter = {
+    enable = mkEnableOption "jupyter";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    # home.packages = with pkgs; [
+    #   evcxr
+    # ];
+
+    # modules.python.extraPythonPackages = p: [
+    #   p.jupyter
+    #   p.notebook
+    # ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          ms-toolsai.jupyter
+          ms-toolsai.jupyter-renderers
+        ];
+
+        userSettings = { };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = { };
+  };
+}

unorganized/user-modules/development/language/nix.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.nix;
+in
+{
+  options.modules.nix = {
+    enable = mkEnableOption "nix";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = with pkgs; [
+      nix-tree
+      nixfmt-rfc-style
+      nixd
+    ];
+
+    # Add nix tree
+    xdg.desktopEntries.nix-tree = {
+      exec = "${pkgs.nix-tree}/bin/nix-tree";
+      name = "Nix Tree";
+      terminal = true;
+      type = "Application";
+    };
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [ jnoortheen.nix-ide ];
+
+        userSettings = {
+          "[nix]" = {
+            "editor.tabSize" = 2;
+          };
+          "nix.enableLanguageServer" = true;
+          "nix.serverPath" = "nixd";
+          "nix.serverSettings" = {
+            nixd = {
+              formatting = {
+                command = [ "nixfmt" ];
+              };
+            };
+          };
+        };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = {
+
+    };
+  };
+}

unorganized/user-modules/development/language/python.nix

@@ -0,0 +1,57 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.python;
+in
+{
+  options.modules.python = {
+    enable = mkEnableOption "python";
+    extraPythonPackages = mkOption {
+      type = types.functionTo (types.listOf types.package) // {
+        merge =
+          loc: defs: p:
+          lib.concatMap (def: (def.value p)) defs;
+      };
+      default = p: [ ];
+      description = "Extra Python packages to install";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = [ ];
+
+    # Allow unfree
+    modules.unfree.allowedPackages = [
+      "vscode-extension-MS-python-vscode-pylance"
+    ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          ms-python.python
+          ms-python.debugpy
+          ms-python.vscode-pylance
+          ms-python.black-formatter
+        ];
+
+        userSettings = {
+          "python.defaultInterpreterPath" = "\${env:PYTHONINTERPRETER}";
+          "[python]" = {
+            "editor.defaultFormatter" = "ms-python.black-formatter";
+          };
+        };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = { };
+  };
+}

unorganized/user-modules/development/language/rust.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.rust;
+in
+{
+  options.modules.rust = {
+    enable = mkEnableOption "rust";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = with pkgs; [
+      # rustup
+      # rustc
+      # cargo
+      # gcc
+      # lldb
+      # bacon
+      # rust-analyzer
+      # rustfmt
+      # clippy
+      # evcxr
+    ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          rust-lang.rust-analyzer
+          vadimcn.vscode-lldb
+          tamasfe.even-better-toml
+          serayuzgur.crates
+        ];
+
+        userSettings = {
+          "[rust]" = {
+            "editor.inlayHints.enabled" = "off";
+          };
+          "rust-analyzer.check.command" = "clippy";
+          "rust-analyzer.showUnlinkedFileNotification" = false;
+        };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = {
+      plugins.rustaceanvim = {
+        enable = true;
+      };
+    };
+  };
+}

unorganized/user-modules/development/language/tex.nix

@@ -0,0 +1,69 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.tex;
+in
+{
+  options.modules.tex = {
+    enable = mkEnableOption "tex";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = with pkgs; [
+      (texlive.combine {
+        inherit (texlive) scheme-full;
+      })
+    ];
+
+    # Pygments for minted
+    modules.python.extraPythonPackages = p: [
+      p.pygments
+    ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [ jnoortheen.nix-ide ];
+
+        userSettings = {
+          "[tex]" = { };
+        };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = {
+      extraConfigVim = ''
+        " Enforce latexmk
+        let g:vimtex_compiler_method = 'latexmk'
+
+        " Set latexmk compilation settings
+        let g:vimtex_compiler_latexmk = {
+          \ 'options': [
+          \   '-shell-escape',
+          \   '-verbose',
+          \   '-file-line-error',
+          \   '-synctex=1',
+          \   '-interaction=nonstopmode',
+          \ ],
+          \}
+      '';
+
+      # Vimtex plugin
+      plugins.vimtex = {
+        enable = true;
+        texlivePackage = null;
+        settings = {
+          view_method = "zathura";
+        };
+      };
+    };
+  };
+}

unorganized/user-modules/development/systemwide.nix

@@ -0,0 +1,6 @@
+{
+  docker = {
+    virtualisation.docker.enable = true;
+    machine.sudo-groups = [ "docker" ];
+  };
+}

unorganized/user-modules/development/utility/docker.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.docker;
+in
+{
+  options.modules.docker = {
+    enable = mkEnableOption "docker";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = with pkgs; [
+      docker
+      docker-compose
+    ];
+
+    # Allow unfree
+    modules.unfree.allowedPackages = [
+    ];
+
+    # VSCode configuration
+    programs.vscode = {
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          ms-azuretools.vscode-docker
+        ];
+
+        userSettings = {
+        };
+      };
+    };
+
+    # Neovim configuration
+    programs.nixvim = { };
+  };
+}

unorganized/user-modules/discord/default.nix

@@ -0,0 +1,22 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.discord;
+in
+{
+  options.modules.discord = {
+    enable = mkEnableOption "discord";
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [ "discord" ];
+
+    home.packages = with pkgs; [ discord ];
+  };
+}

unorganized/user-modules/eduvpn/default.nix

@@ -0,0 +1,23 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.eduvpn;
+in
+{
+  options.modules.eduvpn = {
+    enable = mkEnableOption "EduVPN";
+  };
+
+  config = mkIf cfg.enable {
+    # Development packages
+    home.packages = with pkgs; [
+      eduvpn-client
+    ];
+  };
+}

unorganized/user-modules/feishin/default.nix

@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.feishin;
+in
+{
+  options.modules.feishin.enable = mkEnableOption "feishin";
+
+  config = mkIf cfg.enable {
+    # TODO: Move to audioling
+    home.packages = with pkgs; [ feishin ];
+
+    # TODO: Remove exception once no longer required by feishin
+    nixpkgs.config.permittedInsecurePackages = [
+      "electron-33.4.11"
+      "freeimage-3.18.0-unstable-2024-04-18"
+    ];
+  };
+}

unorganized/user-modules/flatpak/default.nix

@@ -0,0 +1,25 @@
+{
+  lib,
+  config,
+  ...
+}:
+
+with lib;
+{
+  options.modules.flatpak = {
+    enable = mkEnableOption "flatpak";
+    remotes = mkOption {
+      type = types.attrsOf types.str;
+      default = {
+        flathub = "https://dl.flathub.org/repo/flathub.flatpakrepo";
+        flathub-beta = "https://dl.flathub.org/beta-repo/flathub-beta.flatpakrepo";
+      };
+      description = "A set of flatpak repositories to add.";
+    };
+  };
+
+  config = mkIf config.modules.flatpak.enable {
+    services.flatpak.enableModule = true;
+    services.flatpak.remotes = config.modules.flatpak.remotes;
+  };
+}

unorganized/user-modules/flatpak/systemwide.nix

@@ -0,0 +1,5 @@
+{
+  flatpak = {
+    # services.flatpak.enable = true;
+  };
+}

unorganized/user-modules/fontconfig/default.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.fontconfig;
+
+  aliasConfig = font: ''
+    <alias>
+      <family>${font.name}</family>
+
+      <prefer>
+        <family>${font.name}</family>
+    ${concatStrings (map (font: "    <family>${font}</family>\n") font.fallbackFonts)}
+      </prefer>
+    </alias>
+  '';
+
+  configContent = concatStrings (
+    map (
+      font: aliasConfig config.desktop.theming.fonts.pkgs.${font}
+    ) config.desktop.theming.fonts.installed
+  );
+in
+{
+  options.modules.fontconfig = {
+    enable = mkEnableOption "fontconfig";
+  };
+
+  config = mkIf cfg.enable {
+    fonts.fontconfig = {
+      enable = true;
+
+      defaultFonts = {
+        serif = [ config.desktop.theming.fonts.serif.name ];
+        sansSerif = [ config.desktop.theming.fonts.sansSerif.name ];
+        monospace = [ config.desktop.theming.fonts.monospace.name ];
+        emoji = [ config.desktop.theming.fonts.emoji.name ];
+      };
+    };
+
+    home.file.".config/fontconfig/conf.d/20-family-fallbacks.conf" = {
+      enable = true;
+
+      # text = ''
+      #   <?xml version="1.0"?>
+      #   <fontconfig>
+
+      #   ${configContent}
+      #   </fontconfig>
+      # '';
+      text = ''
+        <?xml version='1.0'?>
+        <!DOCTYPE fontconfig SYSTEM 'urn:fontconfig:fonts.dtd'>
+        <fontconfig>
+
+        ${configContent}
+        </fontconfig>
+      '';
+    };
+  };
+}

unorganized/user-modules/gaming/default.nix

@@ -0,0 +1,12 @@
+{ ... }:
+
+{
+  imports = [
+    ./emulators/pcsx2.nix
+    ./emulators/retroarch.nix
+    ./emulators/ryujinx.nix
+    ./launchers/es-de.nix
+    ./launchers/modrinth.nix
+    ./launchers/steam.nix
+  ];
+}

unorganized/user-modules/gaming/emulators/pcsx2.nix

@@ -0,0 +1,22 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.pcsx2;
+in
+{
+  options.modules.pcsx2 = {
+    enable = mkEnableOption "pcsx2";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      pcsx2
+    ];
+  };
+}

unorganized/user-modules/gaming/emulators/retroarch.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.retroarch;
+in
+{
+  options.modules.retroarch = {
+    enable = mkEnableOption "RetroArch";
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [
+      "libretro-fbalpha2012"
+      "libretro-fbneo"
+      "libretro-fmsx"
+      "libretro-genesis-plus-gx"
+      "libretro-mame2000"
+      "libretro-mame2003"
+      "libretro-mame2003-plus"
+      "libretro-mame2010"
+      "libretro-mame2015"
+      "libretro-opera"
+      "libretro-picodrive"
+      "libretro-snes9x"
+      "libretro-snes9x2002"
+      "libretro-snes9x2005"
+      "libretro-snes9x2005-plus"
+      "libretro-snes9x2010"
+    ];
+
+    home.packages = with pkgs; [
+      # retroarch-full
+      retroarch-free
+    ];
+  };
+}

unorganized/user-modules/gaming/emulators/ryujinx.nix

@@ -0,0 +1,25 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.ryujinx;
+in
+{
+  options.modules.ryujinx = {
+    enable = mkEnableOption "ryujinx";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      ryubing
+    ];
+
+    # TODO: Make more general
+    wayland.windowManager.river.settings.rule-add."-app-id"."'Ryujinx'" = "fullscreen";
+  };
+}

unorganized/user-modules/gaming/launchers/es-de.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  config,
+  pkgs,
+  system,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.es-de;
+in
+{
+  options.modules.es-de = {
+    enable = mkEnableOption "Emulation Station Desktop Edition";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      emulationstation-de
+    ];
+
+    home.sessionVariables = {
+      ESDE_APPDATA_DIR = "$HOME/.config/ES-DE";
+    };
+
+    # TODO: Remove exception once no longer required by es-de
+    nixpkgs.config.permittedInsecurePackages = [
+      "freeimage-3.18.0-unstable-2024-04-18"
+    ];
+
+    # TODO: Remove once emulationstation-de fixes the issue
+    # TODO: If not fixed, at least pin the specific commit properly
+    # nixpkgs.overlays =
+    #   let
+    #     pkgs-stable = import (fetchTarball {
+    #       url = "https://github.com/NixOS/nixpkgs/archive/nixos-24.11.tar.gz";
+    #       sha256 = "1wr1xzkw7v8biqqjcr867gbpqf3kibkgly36lcnhw0glvkr1i986";
+    #     }) { inherit system; };
+    #   in
+    #   [
+    #     (final: prev: {
+    #       libgit2 = pkgs-stable.libgit2;
+    #     })
+    #   ];
+  };
+}

unorganized/user-modules/gaming/launchers/modrinth.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.modrinth;
+in
+{
+  options.modules.modrinth = {
+    enable = mkEnableOption "modrinth";
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [
+      "modrinth-app"
+      "modrinth-app-unwrapped"
+    ];
+
+    home.packages = with pkgs; [
+      modrinth-app
+    ];
+  };
+}

unorganized/user-modules/gaming/launchers/steam.nix

@@ -0,0 +1,16 @@
+{
+  config,
+  lib,
+  ...
+}:
+
+with lib;
+{
+  options.modules.steam = {
+    enable = mkEnableOption "steam";
+  };
+
+  config = mkIf config.modules.steam.enable {
+    # Steam must be installed systemwide as of time of writing
+  };
+}

unorganized/user-modules/gaming/systemwide.nix

@@ -0,0 +1,20 @@
+{
+  steam =
+    { pkgs, ... }:
+    {
+      modules.unfree.allowedPackages = [
+        "steam"
+        "steam-original"
+        "steam-unwrapped"
+      ];
+
+      programs.steam.enable = true;
+
+      # Make steam create desktop entries in a subfolder
+      programs.steam.package = pkgs.steam.override {
+        extraBwrapArgs = [
+          "--bind $HOME/.local/share/applications/Steam $HOME/.local/share/applications"
+        ];
+      };
+    };
+}

unorganized/user-modules/git/default.nix

@@ -0,0 +1,53 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.git;
+in
+{
+  options.modules.git = {
+    enable = mkEnableOption "git";
+
+    user = mkOption {
+      type = types.str;
+      description = "Default user name to use.";
+    };
+
+    email = mkOption {
+      type = types.str;
+      description = "Default user email to use.";
+    };
+
+    ignores = mkOption {
+      type = types.listOf types.str;
+      default = [ ];
+      description = "Paths to globally ignore";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      git
+      lazygit
+    ];
+
+    programs.git = {
+      enable = true;
+
+      extraConfig = {
+        pull = {
+          rebase = false;
+        };
+      };
+
+      userName = cfg.user;
+      userEmail = cfg.email;
+      ignores = cfg.ignores;
+    };
+  };
+}

unorganized/user-modules/keyring/default.nix

@@ -0,0 +1,23 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.keyring;
+in
+{
+  options.modules.keyring = {
+    enable = mkEnableOption "keyring";
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      seahorse
+    ];
+    services.gnome-keyring.enable = true;
+  };
+}

unorganized/user-modules/keyring/systemwide.nix

@@ -0,0 +1,7 @@
+{
+  keyring = {
+    services.gnome.gnome-keyring.enable = true;
+    security.pam.services.greetd.enableGnomeKeyring = true;
+    security.pam.services.login.enableGnomeKeyring = true;
+  };
+}

unorganized/user-modules/languagetool/default.nix

@@ -0,0 +1,16 @@
+{ lib, config, ... }:
+
+with lib;
+{
+  imports = [
+    ./eloquent.nix
+  ];
+
+  options.modules.languagetool = {
+    enable = mkEnableOption "languagetool";
+  };
+
+  config = mkIf config.modules.languagetool.enable {
+    modules.eloquent.enable = mkDefault true;
+  };
+}

unorganized/user-modules/languagetool/eloquent.nix

@@ -0,0 +1,17 @@
+{ lib, config, ... }:
+
+with lib;
+{
+  options.modules.eloquent = {
+    enable = mkEnableOption "eloquent";
+  };
+
+  config = mkIf config.modules.eloquent.enable {
+    modules.flatpak.enable = true;
+
+    services.flatpak.packages = [
+      "flathub:app/re.sonny.Eloquent//stable"
+      "flathub:app/org.kde.kdenlive//stable"
+    ];
+  };
+}

unorganized/user-modules/mako/default.nix

@@ -0,0 +1,31 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.mako;
+  theme = config.desktop.theming;
+  colors = theme.colors;
+in
+{
+  options.modules.mako.enable = mkEnableOption "mako";
+
+  config = mkIf cfg.enable {
+    services.mako = {
+      enable = true;
+      anchor = "top-right";
+      defaultTimeout = 5000;
+      backgroundColor = "#${colors.bg}ff";
+      textColor = "#${colors.fg}ff";
+      borderColor = "#${colors.fg}ff";
+      progressColor = "#${colors.accent}ff";
+      borderRadius = 0;
+      borderSize = theme.layout.borderSize;
+      font = "${theme.fonts.monospace.name} ${toString theme.fonts.monospace.recommendedSize}";
+    };
+  };
+}

unorganized/user-modules/neovim/default.nix

@@ -0,0 +1,191 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.neovim;
+  theme = config.desktop.theming;
+  colors = theme.colors;
+in
+{
+  options.modules.neovim = {
+    enable = mkEnableOption "neovim";
+  };
+
+  config = mkIf cfg.enable {
+    programs.nixvim = {
+      enable = true;
+      defaultEditor = true;
+      viAlias = true;
+      vimAlias = true;
+
+      extraPackages = with pkgs; [ ];
+
+      opts = {
+        number = true;
+        relativenumber = true;
+
+        signcolumn = "yes";
+
+        ignorecase = true;
+        smartcase = true;
+
+        tabstop = 4;
+        shiftwidth = 4;
+        softtabstop = 0;
+        expandtab = true;
+        smarttab = true;
+
+        list = true;
+        listchars = "tab:»┈«,trail:·,extends:→,precedes:←,nbsp:␣";
+      };
+
+      diagnostic.settings = {
+        enable = true;
+        signs = true;
+        underline = true;
+        update_in_insert = true;
+      };
+
+      extraConfigLua = ''
+        vim.fn.sign_define("DiagnosticSignError",
+          {text = "", texthl = "DiagnosticSignError"})
+        vim.fn.sign_define("DiagnosticSignWarn",
+          {text = "", texthl = "DiagnosticSignWarn"})
+        vim.fn.sign_define("DiagnosticSignInfo",
+          {text = "", texthl = "DiagnosticSignInfo"})
+        vim.fn.sign_define("DiagnosticSignHint",
+          {text = "💡", texthl = "DiagnosticSignHint"})
+      '';
+
+      keymaps = [
+        # Save shortcut
+        {
+          action = ":update<CR>";
+          key = "<C-s>";
+          mode = "n";
+        }
+        {
+          action = "<C-o>:update<CR>";
+          key = "<C-s>";
+          mode = "i";
+        }
+
+        # Neo tree
+        {
+          action = ":Neotree action=focus reveal toggle<CR>";
+          key = "<leader>n";
+          mode = "n";
+          options.silent = true;
+        }
+      ];
+
+      autoCmd = [
+        {
+          desc = "Automatic formatting";
+          event = "BufWritePre";
+          callback = {
+            __raw = ''
+              function()
+                vim.lsp.buf.format {
+                  async = false,
+                }
+              end
+            '';
+          };
+        }
+      ];
+
+      highlight = {
+        Comment = {
+          italic = true;
+          fg = theme.schemeColors.withHashtag.base03; # TODO: Come up with a good name colors.muted maybe?
+        };
+
+      };
+
+      plugins.lsp = {
+        enable = true;
+      };
+
+      #plugins.treesitter = {
+      #  enable = true;
+      #};
+
+      plugins.cmp = {
+        enable = true;
+
+        settings = {
+          mapping = {
+            "<C-Space>" = "cmp.mapping.complete()";
+            "<C-d>" = "cmp.mapping.scroll_docs(-4)";
+            "<C-e>" = "cmp.mapping.close()";
+            "<C-f>" = "cmp.mapping.scroll_docs(4)";
+            "<CR>" = "cmp.mapping.confirm({ select = true })";
+            "<S-Tab>" = "cmp.mapping(cmp.mapping.select_prev_item(), {'i', 's'})";
+            "<Tab>" = "cmp.mapping(cmp.mapping.select_next_item(), {'i', 's'})";
+          };
+          sources = [
+            { name = "path"; }
+            { name = "nvim_lsp"; }
+          ];
+        };
+      };
+
+      plugins.web-devicons = {
+        enable = true;
+      };
+
+      plugins.neo-tree = {
+        enable = true;
+
+        closeIfLastWindow = true;
+        window = {
+          width = 30;
+          autoExpandWidth = true;
+        };
+
+        extraOptions = {
+          default_component_configs.git_status.symbols = {
+            # Change type
+            added = "+";
+            deleted = "✕";
+            modified = "✦";
+            renamed = "→";
+
+            # Status type
+            untracked = "?";
+            ignored = "▫";
+            unstaged = "□";
+            staged = "■";
+            conflict = "‼";
+          };
+        };
+      };
+
+      #plugins.cmp-nvim-lsp.enable = true;
+
+      plugins.gitsigns = {
+        enable = true;
+        settings.current_line_blame = true;
+      };
+
+      #plugins.copilot-vim = {
+      #  enable = true;
+      #};
+
+      # plugins.vimtex = {
+      #   enable = true;
+      #   texlivePackage = null;
+      #   settings = {
+      #     view_method = "zathura";
+      #   };
+      # };
+    };
+    programs.neovim.defaultEditor = true;
+  };
+}

unorganized/user-modules/obsidian/default.nix

@@ -0,0 +1,22 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.obsidian;
+in
+{
+  options.modules.obsidian = {
+    enable = mkEnableOption "obsidian";
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [ "obsidian" ];
+
+    home.packages = with pkgs; [ obsidian ];
+  };
+}

unorganized/user-modules/rofi/default.nix

@@ -0,0 +1,62 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.rofi;
+  theme = config.desktop.theming;
+  colors = theme.colors;
+in
+{
+  options.modules.rofi.enable = mkEnableOption "rofi";
+
+  config = mkIf cfg.enable {
+    programs.rofi = {
+      enable = true;
+      terminal = config.default.terminal;
+      package = pkgs.rofi-wayland;
+      font = "${theme.fonts.interface.name} ${toString (theme.fonts.interface.recommendedSize)}";
+      theme =
+        let
+          inherit (config.lib.formats.rasi) mkLiteral;
+        in
+        {
+          "*" = {
+            background-color = mkLiteral "rgba(0, 0, 0, 0%)";
+            border-color = mkLiteral "#${colors.fg}";
+            text-color = mkLiteral "#${colors.fg}";
+          };
+          mainbox = {
+            background-color = mkLiteral "#${colors.bg}";
+            border = mkLiteral "${toString theme.layout.borderSize}px";
+          };
+          element-text = {
+            highlight = mkLiteral "#${colors.fg-search}";
+          };
+          inputbar = {
+            children = mkLiteral "[textbox-search, entry]";
+          };
+          listview = {
+            padding = mkLiteral "2px 0px";
+          };
+          textbox-search = {
+            expand = false;
+            content = "> ";
+          };
+          "inputbar, message" = {
+            padding = mkLiteral "2px";
+          };
+          element = {
+            padding = mkLiteral "1px 2px 3px 2px";
+          };
+          "element selected" = {
+            background-color = mkLiteral "#${colors.border-unfocused}";
+          };
+        };
+    };
+  };
+}

unorganized/user-modules/rofi/rofi-rbw.nix

@@ -0,0 +1,30 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.rofi-rbw;
+in
+{
+  options.modules.rofi-rbw.enable = mkEnableOption "rofi-rbw";
+
+  config = mkIf cfg.enable {
+    modules.rofi.enable = true;
+
+    home.packages = [ pkgs.rofi-rbw ];
+
+    # TODO: Move to separate module and make configurable
+    programs.rbw = {
+      enable = true;
+      settings = {
+        base_url = "https://keys.bulthuis.dev";
+        email = "jan@bulthuis.dev";
+        pinentry = pkgs.pinentry;
+      };
+    };
+  };
+}

unorganized/user-modules/scripts/default.nix

@@ -0,0 +1,21 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.scripts;
+in
+{
+  options.modules.scripts.enable = mkEnableOption "scripts";
+
+  config = mkIf cfg.enable {
+    # home.packages = with pkgs; map (path: (writeShellScriptBin "${path}" (readFile path))) scripts;
+    home.packages = with pkgs; [
+      (writeShellScriptBin "mkenv" (readFile ./mkenv.sh))
+    ];
+  };
+}

unorganized/user-modules/scripts/mkenv.sh

@@ -0,0 +1,53 @@
+setupEnv () {
+    echo "Setting up .envrc"
+    if git rev-parse --is-inside-work-tree > /dev/null 2>&1; then
+        insideGit;
+    else
+        outsideGit;
+    fi;
+}
+
+insideGit () {
+    echo "Inside of git environment"
+    cd $(git rev-parse --show-toplevel)
+    echo "Setting up inside $PWD"
+    echo "git add -f --intent-to-add flake.nix
+use flake ." > .envrc
+
+    echo "Enabling environment"
+    direnv allow
+
+    setupFlake
+}
+
+outsideGit () {
+    echo "Outside of git environment"
+    echo "use flake . --impure" > .envrc
+
+    echo "Enabling environment"
+    direnv allow
+
+    setupFlake
+}
+
+setupFlake () {
+    if [ -e flake.nix ]; then
+        echo "flake.nix already exists."
+        return
+    fi;
+
+    echo "Setting up flake.nix"
+    echo "{
+  inputs.devenv.url = \"git+https://git.bulthuis.dev/Jan/dotfiles\";
+  outputs = { devenv, ... }: devenv.lib.mkShell { };
+}" > flake.nix
+}
+
+echo "Creating dev environment"
+
+if [ -e .envrc ]; then
+    echo ".envrc already exists."
+    setupFlake
+else
+    setupEnv
+fi;

unorganized/user-modules/shell/bash.nix

@@ -0,0 +1,21 @@
+{
+  lib,
+  config,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.bash;
+in
+{
+  options.modules.bash = {
+    enable = mkEnableOption "bash";
+  };
+
+  config.programs.bash = {
+    enable = cfg.enable;
+
+    shellAliases = config.modules.shell.aliases;
+  };
+}

unorganized/user-modules/shell/default.nix

@@ -0,0 +1,17 @@
+{
+  lib,
+  ...
+}:
+
+with lib;
+{
+  options.modules.shell = {
+    aliases = mkOption {
+      type = types.attrsOf types.str;
+      default = {
+        "..." = "cd ../..";
+      };
+      description = "Shell aliases";
+    };
+  };
+}

unorganized/user-modules/shell/fish.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.fish;
+in
+{
+  options.modules.fish = {
+    enable = mkEnableOption "fish";
+
+    plugins = {
+      done = mkEnableOption "done";
+      fzf = mkEnableOption "fzf";
+      grc = mkEnableOption "grc";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    # Make bash load into fish
+    # Bash will remain the default shell as fish is not POSIX compliant.
+    modules.bash.enable = true;
+    programs.bash.initExtra = ''
+      if [[ $(${pkgs.procps}/bin/ps --no-header --pid=$PPID --format=comm) != "fish" && -z ''${BASH_EXECUTION_STRING} ]]
+      then
+        shopt -q login_shell && LOGIN_OPTION='--login' || LOGIN_OPTION=""
+        exec ${pkgs.fish}/bin/fish $LOGIN_OPTION
+      fi
+    '';
+
+    # Actual fish configuration
+    programs.fish = {
+      enable = true;
+
+      shellAliases = config.modules.shell.aliases;
+
+      plugins = [
+        (mkIf cfg.plugins.done {
+          name = "done";
+          src = pkgs.fishPlugins.done.src;
+        })
+        (mkIf cfg.plugins.fzf {
+          name = "fzf";
+          src = pkgs.fishPlugins.fzf-fish.src;
+        })
+        (mkIf cfg.plugins.grc {
+          name = "grc";
+          src = pkgs.fishPlugins.grc.src;
+        })
+      ];
+    };
+
+    # Fish plugin dependencies
+    home.packages = with pkgs; [
+      (mkIf cfg.plugins.fzf fzf)
+      (mkIf cfg.plugins.grc grc)
+    ];
+  };
+}

unorganized/user-modules/spotify/default.nix

@@ -0,0 +1,24 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.spotify;
+in
+{
+  options.modules.spotify.enable = mkEnableOption "spotify";
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [
+      "spotify"
+    ];
+
+    home.packages = with pkgs; [
+      spotify
+    ];
+  };
+}

unorganized/user-modules/terminal/default.nix

@@ -0,0 +1,17 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+{
+  options.default.terminal = mkOption {
+    type = types.str;
+    # TODO: Make sure everything works even without a default value here
+    # Maybe make sure most gui applications do not exist in the default specialisation
+    default = "foot";
+    description = "Default terminal application";
+  };
+}

unorganized/user-modules/terminal/foot/default.nix

@@ -0,0 +1,35 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.foot;
+in
+{
+  options.modules.foot.enable = mkEnableOption "foot";
+
+  config = mkIf cfg.enable {
+    default.terminal = mkDefault "${pkgs.foot}/bin/foot";
+
+    programs.foot = {
+      enable = true;
+      settings = {
+        main =
+          let
+            font = config.desktop.theming.fonts.monospace.name;
+            size = toString config.desktop.theming.fonts.monospace.recommendedSize;
+          in
+          {
+            font = mkForce "${font}:style=Regular:size=${size}";
+            font-bold = "${font}:style=Bold:size=${size}";
+            font-italic = "${font}:style=Italic:size=${size}";
+            font-bold-italic = "${font}:style=Bold Italic:size=${size}";
+          };
+      };
+    };
+  };
+}

unorganized/user-modules/vscode/default.nix

@@ -0,0 +1,103 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.vscode;
+  theme = config.desktop.theming;
+in
+{
+  options.modules.vscode = {
+    enable = mkEnableOption "vscode";
+    codeFont = mkOption {
+      type = types.anything;
+      default = theme.fonts.pkgs."Fira Code";
+    };
+    fallbackFont = mkOption {
+      type = types.anything;
+      default = theme.fonts.pkgs."Symbols Nerd Font Mono";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [
+      "vscode"
+      "vscode-extension-github-copilot"
+      "vscode-extension-github-copilot-chat"
+      "vscode-extension-ms-vsliveshare-vsliveshare"
+      "vscode-extension-ms-vscode-remote-remote-ssh"
+    ];
+
+    desktop.theming.fonts.extraFonts = [ cfg.codeFont ];
+
+    programs.vscode = {
+      enable = true;
+
+      mutableExtensionsDir = false;
+      profiles.default = {
+        extensions = with pkgs.vscode-extensions; [
+          eamodio.gitlens
+          ms-vscode.hexeditor
+          mkhl.direnv
+          usernamehw.errorlens
+          gruntfuggly.todo-tree
+          github.copilot
+          github.copilot-chat
+          tomoki1207.pdf
+          ms-vsliveshare.vsliveshare
+          ms-vscode-remote.remote-ssh
+        ];
+
+        userSettings =
+          let
+            font-family = mkForce "'${cfg.codeFont.name}', '${cfg.fallbackFont.name}'";
+            # TODO: Move the conversion factor to theme settings
+            font-size = mkForce cfg.codeFont.recommendedSize; # Convert pt to px
+          in
+          {
+            # Font setup
+            "editor.fontFamily" = font-family;
+            "editor.inlayHints.fontFamily" = font-family;
+            "editor.inlineSuggest.fontFamily" = font-family;
+            "editor.fontSize" = font-size;
+            "editor.fontLigatures" = true;
+            "terminal.integrated.fontFamily" = font-family;
+            "terminal.integrated.fontSize" = font-size;
+            "chat.editor.fontFamily" = font-family; # TODO: Change this font to the standard UI font
+            "chat.editor.fontSize" = font-size;
+            "debug.console.fontFamily" = font-family;
+            "debug.console.fontSize" = font-size;
+            "scm.inputFontFamily" = font-family; # TODO: Change this font to the standard UI font
+            "scm.inputFontSize" = font-size;
+            "markdown.preview.fontFamily" = mkForce theme.fonts.sansSerif.name; # TODO: Change this font to the standard UI font
+            "markdown.preview.fontSize" = mkForce theme.fonts.sansSerif.recommendedSize;
+
+            # Formatting
+            "editor.formatOnSave" = true;
+            "editor.tabSize" = 4;
+
+            # Layout
+            "window.menuBarVisibility" = "hidden";
+
+            # Git settings
+            "git.autofetch" = true;
+            "git.enableSmartCommit" = false;
+            "git.suggestSmartCommit" = false;
+
+            # Disable update notifications
+            "update.mode" = "none";
+
+            # TODO: Move to direnv module
+            # Ignore direnv folder
+            "files.exclude" = {
+              ".direnv" = true;
+            };
+          };
+      };
+    };
+  };
+}

unorganized/user-modules/whatsapp/default.nix

@@ -0,0 +1,22 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.whatsapp;
+in
+{
+  options.modules.whatsapp = {
+    enable = mkEnableOption "whatsapp";
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [ "whatsapp-for-linux" ];
+
+    home.packages = with pkgs; [ whatsapp-for-linux ];
+  };
+}

unorganized/user-modules/winbox/default.nix

@@ -0,0 +1,22 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.winbox;
+in
+{
+  options.modules.winbox = {
+    enable = mkEnableOption "winbox";
+  };
+
+  config = mkIf cfg.enable {
+    modules.unfree.allowedPackages = [ "winbox" ];
+
+    home.packages = with pkgs; [ winbox ];
+  };
+}

unorganized/user-modules/wprs/default.nix

@@ -0,0 +1,83 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.wprs;
+
+  wprsHostConfigurationModule = types.submodule {
+    options = {
+      name = mkOption {
+        type = types.str;
+        description = "Command name.";
+      };
+      command = mkOption {
+        type = types.str;
+        description = "Command to run.";
+      };
+    };
+  };
+in
+{
+  options.modules.wprs = {
+    enable = mkEnableOption "Enable wprs";
+    hosts = mkOption {
+      type = types.attrsOf (types.listOf wprsHostConfigurationModule);
+      default = { };
+      description = "wprs commands to add as desktop files";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      wprs
+    ];
+
+    xdg.desktopEntries = (
+      listToAttrs (
+        map
+          (entry: {
+            name = "wprs${
+              builtins.substring 0 12 (builtins.hashString "sha256" "${entry.name} (${entry.comment})")
+            }";
+            value = entry // {
+              type = "Application";
+              terminal = false;
+              genericName = entry.comment;
+            };
+          })
+          (
+            concatMap (
+              entry:
+              let
+                host = entry.name;
+                commands = entry.value;
+                hostEntries = [
+                  {
+                    name = "Wprs - Attach";
+                    comment = host;
+                    exec = "wprs --pulseaudio-forwarding False ${host} attach";
+                  }
+                  {
+                    name = "Wprs - Detach";
+                    comment = host;
+                    exec = "wprs ${host} detach";
+                  }
+                ];
+                commandEntries = map (command: {
+                  name = "Wprs - ${command.name}";
+                  comment = host;
+                  exec = "wprs --pulseaudio-forwarding False ${host} run \"${command.command}\"";
+                }) commands;
+              in
+              (hostEntries ++ commandEntries)
+            ) (attrsToList cfg.hosts)
+          )
+      )
+    );
+  };
+}

unorganized/user-modules/xpra/default.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+
+with lib;
+let
+  cfg = config.modules.xpra;
+in
+{
+  options.modules.xpra = {
+    enable = mkEnableOption "Enable xpra";
+    hosts = mkOption {
+      type = types.listOf types.str;
+      default = { };
+      description = "xpra hosts";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = with pkgs; [
+      xpra
+    ];
+
+    xdg.desktopEntries = (
+      listToAttrs (
+        map
+          (entry: {
+            name = "xpra${
+              builtins.substring 0 12 (builtins.hashString "sha256" "${entry.name} (${entry.comment})")
+            }";
+            value = entry // {
+              type = "Application";
+              terminal = false;
+              genericName = entry.comment;
+            };
+          })
+          (
+            concatMap (
+              host:
+              let
+                uri = "tcp://${host}:15151/7";
+              in
+              [
+                {
+                  name = "Xpra - Attach";
+                  comment = host;
+                  exec = "xpra attach --min-quality=100 --min-speed=100 --encoding=png --speaker=off ${uri}";
+                }
+                {
+                  name = "Xpra - Detach";
+                  comment = host;
+                  exec = "xpra detach ${uri}";
+                }
+              ]
+            ) cfg.hosts
+          )
+      )
+    );
+  };
+}

unorganized/user-modules/zathura/default.nix

@@ -0,0 +1,36 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.modules.zathura;
+  colors = config.desktop.theming.colors;
+in
+{
+  options.modules.zathura.enable = lib.mkEnableOption "zathura";
+
+  config = lib.mkIf cfg.enable {
+    programs.zathura = {
+      enable = true;
+
+      options = {
+        guioptions = "none";
+        recolor = true;
+        recolor-keephue = false;
+        recolor-darkcolor = lib.mkForce "#${colors.accent}";
+        recolor-lightcolor = lib.mkForce "#${colors.bg}";
+      };
+    };
+
+    xdg.mimeApps = {
+      enable = true;
+
+      defaultApplications = {
+        "application/pdf" = "zathura";
+      };
+    };
+  };
+}